net-libs/tox: version bump to 0.2.5

Package-Manager: Portage-2.3.40, Repoman-2.3.9

3 files changed, 100 insertions, 26 deletions

diff --git a/net-libs/tox/Manifest b/net-libs/tox/Manifest
index b1fd636c002..a8f6d5d5509 100644
--- a/net-libs/tox/Manifest
+++ b/net-libs/tox/Manifest
@@ -1,3 +1,4 @@
 DIST c-toxcore-0.1.10.tar.gz 820090 BLAKE2B 071e530db2dd6ca387a6cd88f1145515ab8741017626fcb744fdc9940263b6c2604b456b6d1357bc78be5e33b544ecf882e608bc7b4a4227d44c5507e5dbad56 SHA512 428fee2d811d0b6d5d005f082aa06f95765794b1a8bc77ec4411bb9ec9085b99675535b88db50f5ad7313850a0bb3c54c4e2e8d8864cea7c0c7d81be9879b157
+DIST c-toxcore-0.2.5.tar.gz 482160 BLAKE2B b56511d9cf7bd3a9d2b9177b33bdbf60ac571f6c95d7ee26e6ecae7c9395d8cdd4f6650025f8b727ad9b825b304c4555efaee0f17d60a26bc5bf599905ec27ab SHA512 a425a106054f29533b43b14cb8916706d04158d91b66cdada0e9e007aebd3f68a253b8519a75ca94bffba3adc57362b4e7c44e9356fce416f081a7eda6a61e18
 DIST tox-0.1.6.tar.lz 314837 BLAKE2B 087a6f5d5ef55709b5f6188d661d556326bb3e6eac33e55f9faf598d433e33dabbd983ab452e948bff97f82cdc336e0fd48d3f0a6ec57551914884a809b9118d SHA512 57ed7cee2c621c57e24f5ab36d68d99414d9820cdb3e8b7c4390818222f9d885f352f9cf76c8eb522c238bebc7d420bcf3cdd5f6ab65b9801aadbd225765166c
 DIST tox-0_pre20160904.tar.gz 395495 BLAKE2B d59358c5ff904b17e9c5297a0ce2aff39777f8dd4bfeba1e5e78a284a5016921794d0e0699f91a99f53428809a859ce959e17b4ae9fffdd691005c377834057d SHA512 c0da52ac908141e97e96510a05431cbfb4b9aae81faf4c136c95e21b90a23e3bbe6db88303e48c0f4f3c74ca954229787564b7aa41bfb462afb0d8f8430cdaa1
diff --git a/net-libs/tox/tox-0.2.5.ebuild b/net-libs/tox/tox-0.2.5.ebuild
new file mode 100644
index 00000000000..71e771406fa
--- /dev/null
+++ b/net-libs/tox/tox-0.2.5.ebuild
@@ -0,0 +1,79 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit cmake-utils systemd user
+
+MY_P="c-toxcore-${PV}"
+DESCRIPTION="Encrypted P2P, messaging, and audio/video calling platform"
+HOMEPAGE="https://tox.chat"
+SRC_URI="https://github.com/TokTok/c-toxcore/archive/v${PV}.tar.gz -> ${MY_P}.tar.gz"
+
+LICENSE="GPL-3+"
+SLOT="0/0.2"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="+av daemon log-debug log-trace +no-log static-libs test"
+
+REQUIRED_USE="^^ ( no-log log-trace log-debug )"
+
+RDEPEND="
+	av? ( media-libs/libvpx:=
+		media-libs/opus )
+	daemon? ( dev-libs/libconfig )
+	>=dev-libs/libsodium-0.6.1:=[asm,urandom]"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+S="${WORKDIR}/${MY_P}"
+
+src_prepare() {
+	cmake-utils_src_prepare
+	# disable tests that need internet
+	for testname in bootstrap lan_discovery tcp_relay tox_many_tcp; do
+		sed -i -e "/^auto_test(${testname})$/d" CMakeLists.txt || die
+	done
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DTRACE=$(usex log-trace)
+		-DDEBUG=$(usex log-debug)
+		-DBUILD_TOXAV=$(usex av)
+		-DMUST_BUILD_TOXAV=$(usex av)
+		-DBUILD_AV_TEST=$(usex av)
+		-DBOOTSTRAP_DAEMON=$(usex daemon)
+		-DENABLE_STATIC=$(usex static-libs)
+	)
+
+	cmake-utils_src_configure
+}
+
+src_install() {
+	cmake-utils_src_install
+
+	if use daemon; then
+		newinitd "${FILESDIR}"/initd tox-dht-daemon
+		newconfd "${FILESDIR}"/confd tox-dht-daemon
+		insinto /etc
+		doins "${FILESDIR}"/tox-bootstrapd.conf
+		systemd_dounit "${FILESDIR}"/tox-bootstrapd.service
+	fi
+
+	find "${D}" -name '*.la' -delete || die
+}
+
+pkg_postinst() {
+	if use daemon; then
+		enewgroup tox
+		enewuser tox -1 -1 -1 tox
+		if [[ -f ${EROOT%/}/var/lib/tox-dht-bootstrap/key ]]; then
+			ewarn "Backwards compatability with the bootstrap daemon might have been"
+			ewarn "broken a while ago. To resolve this issue, REMOVE the following files:"
+			ewarn "    ${EROOT%/}/var/lib/tox-dht-bootstrap/key"
+			ewarn "    ${EROOT%/}/etc/tox-bootstrapd.conf"
+			ewarn "    ${EROOT%/}/run/tox-dht-bootstrap/tox-dht-bootstrap.pid"
+			ewarn "Then just re-emerge net-libs/tox"
+		fi
+	fi
+}
diff --git a/net-libs/tox/tox-9999.ebuild b/net-libs/tox/tox-9999.ebuild
index e7b2b5569ca..6480c17e2cc 100644
--- a/net-libs/tox/tox-9999.ebuild
+++ b/net-libs/tox/tox-9999.ebuild
@@ -1,9 +1,9 @@
-# Copyright 1999-2017 Gentoo Foundation
+# Copyright 1999-2018 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=6
 
-inherit autotools git-r3 user systemd
+inherit cmake-utils git-r3 systemd user
 
 DESCRIPTION="Encrypted P2P, messaging, and audio/video calling platform"
 HOMEPAGE="https://tox.chat"
@@ -11,43 +11,37 @@ SRC_URI=""
 EGIT_REPO_URI="https://github.com/TokTok/c-toxcore.git"
 
 LICENSE="GPL-3+"
-SLOT="0/0.1"
+SLOT="0/0.2"
 KEYWORDS=""
-IUSE="+av daemon log-debug log-error log-info log-trace log-warn +no-log ntox static-libs test"
+IUSE="+av daemon log-debug log-trace +no-log static-libs test"
 
-REQUIRED_USE="^^ ( no-log log-trace log-debug log-info log-warn log-error )"
+REQUIRED_USE="^^ ( no-log log-trace log-debug )"
 
 RDEPEND="
 	av? ( media-libs/libvpx:=
 		media-libs/opus )
 	daemon? ( dev-libs/libconfig )
-	ntox? ( sys-libs/ncurses:0= )
 	>=dev-libs/libsodium-0.6.1:=[asm,urandom]"
 DEPEND="${RDEPEND}
-	test? ( dev-libs/check )
 	virtual/pkgconfig"
 
-src_prepare() {
-	default
-	eautoreconf
-}
-
 src_configure() {
-	econf \
-		$(usex log-trace "--enable-logging --with-log-level=TRACE" "") \
-		$(usex log-debug "--enable-logging --with-log-level=DEBUG" "") \
-		$(usex log-info "--enable-logging --with-log-level=INFO" "") \
-		$(usex log-warn "--enable-logging --with-log-level=WARNING" "") \
-		$(usex log-error "--enable-logging --with-log-level=ERROR" "") \
-		$(use_enable av) \
-		$(use_enable test tests) \
-		$(use_enable ntox) \
-		$(use_enable daemon) \
-		$(use_enable static-libs static)
+	local mycmakeargs=(
+		-DTRACE=$(usex log-trace)
+		-DDEBUG=$(usex log-debug)
+		-DBUILD_TOXAV=$(usex av)
+		-DMUST_BUILD_TOXAV=$(usex av)
+		-DBUILD_AV_TEST=$(usex av)
+		-DBOOTSTRAP_DAEMON=$(usex daemon)
+		-DENABLE_STATIC=$(usex static-libs)
+	)
+
+	cmake-utils_src_configure
 }
 
 src_install() {
-	default
+	cmake-utils_src_install
+
 	if use daemon; then
 		newinitd "${FILESDIR}"/initd tox-dht-daemon
 		newconfd "${FILESDIR}"/confd tox-dht-daemon
@@ -61,8 +55,8 @@ src_install() {
 
 pkg_postinst() {
 	if use daemon; then
-		enewgroup ${PN}
-		enewuser ${PN} -1 -1 -1 ${PN}
+		enewgroup tox
+		enewuser tox -1 -1 -1 tox
 		if [[ -f ${EROOT%/}/var/lib/tox-dht-bootstrap/key ]]; then
 			ewarn "Backwards compatability with the bootstrap daemon might have been"
 			ewarn "broken a while ago. To resolve this issue, REMOVE the following files:"