From 915759fbd6fa3a96435335a1e212c971ffa85d09 Mon Sep 17 00:00:00 2001
From: Marek Szuba <marecki@gentoo.org>
Date: Mon, 6 Nov 2017 12:40:44 +0100
Subject: dev-libs/beignet: bump to 1.3.2

Now with support for llvm-4 and llvm-5!

Package-Manager: Portage-2.3.8, Repoman-2.3.3
---
 dev-libs/beignet/Manifest             |   1 +
 dev-libs/beignet/beignet-1.3.2.ebuild | 102 ++++++++++++++++++++++++++++++++++
 2 files changed, 103 insertions(+)
 create mode 100644 dev-libs/beignet/beignet-1.3.2.ebuild

(limited to 'dev-libs/beignet')

diff --git a/dev-libs/beignet/Manifest b/dev-libs/beignet/Manifest
index 37d86d79568..efea9601469 100644
--- a/dev-libs/beignet/Manifest
+++ b/dev-libs/beignet/Manifest
@@ -1 +1,2 @@
 DIST beignet-1.3.1-source.tar.gz 1136608 SHA256 399b7bc64d674b3092683263f7c085c5592686b9d837817e77857248e5cb561f SHA512 727c8ce68dc39672aa37370ebf2748955925a7cfd58c970c9a641706b45cc31d4a7d3eeebc366ed32ef69add5dd36189814454e5b31f12a6f09ea1a51c810338 WHIRLPOOL 528667a58fbd446e7177edc578543b301205a05fae99d3b1d3782792cac564683e7318fe4e83d81c194ee29fa6cca613e86ce8064f26b551385c8b6c51f4b21e
+DIST beignet-1.3.2-source.tar.gz 1143573 SHA256 c555edba149de23243965a703f39f79fa06f15bcff5a3762b5544b0925010b43 SHA512 ed09a895c2f7e9b6e18687a899f1303dfda95e505c3c2d54bf7598cc4eba6c2fb5926589b19dd294384a4ff3f832c43235b1f03f8b7fd295cd558e78bda1400a WHIRLPOOL 5d1c48bce9e8ffb4928baebce80d5bc50cb6ffb5a6d5f144b7e7258b9d42bdb995a604f98d5d942ef6edea636ba7cd7308b7156b00c9234772d1c1fc597ece02
diff --git a/dev-libs/beignet/beignet-1.3.2.ebuild b/dev-libs/beignet/beignet-1.3.2.ebuild
new file mode 100644
index 00000000000..9b6fbba591a
--- /dev/null
+++ b/dev-libs/beignet/beignet-1.3.2.ebuild
@@ -0,0 +1,102 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python{2_7,3_4,3_5} )
+CMAKE_BUILD_TYPE="Release"
+
+inherit python-any-r1 cmake-multilib flag-o-matic toolchain-funcs
+
+DESCRIPTION="OpenCL implementation for Intel GPUs"
+HOMEPAGE="https://01.org/beignet"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+IUSE="ocl-icd ocl20"
+
+if [[ "${PV}" == "9999" ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://anongit.freedesktop.org/git/beignet.git"
+	KEYWORDS=""
+else
+	KEYWORDS="~amd64"
+	SRC_URI="https://01.org/sites/default/files/${P}-source.tar.gz"
+	S=${WORKDIR}/Beignet-${PV}-Source
+fi
+
+COMMON="media-libs/mesa
+	sys-devel/clang:=
+	sys-devel/llvm:=
+	>=x11-libs/libdrm-2.4.70[video_cards_intel]
+	x11-libs/libXext
+	x11-libs/libXfixes"
+RDEPEND="${COMMON}
+	app-eselect/eselect-opencl"
+DEPEND="${COMMON}
+	${PYTHON_DEPS}
+	ocl-icd? ( dev-libs/ocl-icd )
+	virtual/pkgconfig"
+
+PATCHES=(
+	"${FILESDIR}"/no-debian-multiarch.patch
+	"${FILESDIR}"/${PN}-1.3.1-oclicd_no_upstream_icdfile.patch
+	"${FILESDIR}"/${PN}-1.2.0_no-hardcoded-cflags.patch
+	"${FILESDIR}"/llvm-terminfo.patch
+)
+
+DOCS=(
+	docs/.
+)
+
+pkg_pretend() {
+	if [[ ${MERGE_TYPE} != "binary" ]]; then
+		if tc-is-gcc; then
+			if [[ $(gcc-major-version) -eq 4 ]] && [[ $(gcc-minor-version) -lt 6 ]]; then
+				eerror "Compilation with gcc older than 4.6 is not supported"
+				die "Too old gcc found."
+			fi
+		fi
+	fi
+}
+
+pkg_setup() {
+	python_setup
+}
+
+src_prepare() {
+	# See Bug #593968
+	append-flags -fPIC
+
+	cmake-utils_src_prepare
+	# We cannot run tests because they require permissions to access
+	# the hardware, and building them is very time-consuming.
+	cmake_comment_add_subdirectory utests
+}
+
+multilib_src_configure() {
+	VENDOR_DIR="/usr/$(get_libdir)/OpenCL/vendors/${PN}"
+
+	local mycmakeargs=(
+		-DCMAKE_INSTALL_PREFIX="${VENDOR_DIR}"
+		-DOCLICD_COMPAT=$(usex ocl-icd)
+		$(usex ocl20 "" "-DENABLE_OPENCL_20=OFF")
+	)
+
+	cmake-utils_src_configure
+}
+
+multilib_src_install() {
+	VENDOR_DIR="/usr/$(get_libdir)/OpenCL/vendors/${PN}"
+
+	cmake-utils_src_install
+
+	insinto /etc/OpenCL/vendors/
+	echo "${VENDOR_DIR}/lib/${PN}/libcl.so" > "${PN}-${ABI}.icd" || die "Failed to generate ICD file"
+	doins "${PN}-${ABI}.icd"
+
+	dosym "lib/${PN}/libcl.so" "${VENDOR_DIR}"/libOpenCL.so.1
+	dosym "lib/${PN}/libcl.so" "${VENDOR_DIR}"/libOpenCL.so
+	dosym "lib/${PN}/libcl.so" "${VENDOR_DIR}"/libcl.so.1
+	dosym "lib/${PN}/libcl.so" "${VENDOR_DIR}"/libcl.so
+}
-- 
cgit v1.2.1