From c8913c1764ca5d0d63f76ab00efaee71697b4008 Mon Sep 17 00:00:00 2001
From: Marius Brehler <marbre@linux.sungazer.de>
Date: Fri, 1 Apr 2016 16:52:05 +0200
Subject: dev-python/ipython: Version bump; Bump to EAPI=6

Package-Manager: portage-2.2.26
---
 dev-python/ipython/Manifest             |   1 +
 dev-python/ipython/ipython-4.1.2.ebuild | 137 ++++++++++++++++++++++++++++++++
 2 files changed, 138 insertions(+)
 create mode 100644 dev-python/ipython/ipython-4.1.2.ebuild

(limited to 'dev-python')

diff --git a/dev-python/ipython/Manifest b/dev-python/ipython/Manifest
index af332b8d158..10ce4dd2319 100644
--- a/dev-python/ipython/Manifest
+++ b/dev-python/ipython/Manifest
@@ -2,3 +2,4 @@ DIST ipython-3.2.1.tar.gz 10884249 SHA256 c913adee7ae5b338055274c51a7d2b3cea468b
 DIST ipython-4.0.1.tar.gz 6207566 SHA256 3bd3b78abc4f43b9ea7fa5353a2a9ba01af8ac4aec5d11e78fa5cbcec105432e SHA512 88419feca21c762a8553b4c11661e28b3305742fc89309abfd46b1213da210249b4781b754996835a2cc539569ae7cb816ed26bbaddbf15529eeb6479660265e WHIRLPOOL 58c17378fbcbac94e1585cce0cdd00996f7df20f5781a88e1e7d56b9fe2db81fe3282211dba31e8f54d2e50db869d2cce2670cfebc5c868455f481064e0089c6
 DIST ipython-4.0.3.tar.gz 6207899 SHA256 3a928f59e8ac8dd97858c28390867c87c09510f1f8bbe97e4e9c6b036eb84fc0 SHA512 1e2deb597348757e69aaeadd0632cf984056e5f7278ee5bbbd7b4233581323b07f55685b1891c23dc0977d9f30f7dc734dcf2216bc8876424cdb0f7a9294fecf WHIRLPOOL 1beb60e6daf3cea4609318e87a07307843eeb1002847f8c3c5fbe8e114ab29cb052c810884b410f1e8414437b91c5335048106756e2d88a82a7e440e3ff8fc17
 DIST ipython-4.1.1.tar.gz 4938684 SHA256 1cb340dfdf6ec306b9ded72071742c87fa5247929db7ab704e17defe1975e38f SHA512 ccb24a6d3de5f12a21225387e46ad1b1038910d51d8c0aeb1f4ad6d24751b300295548083f60f3eadec3f29c75370644638b30e6ce391d13f900454e8b3d60a5 WHIRLPOOL f041d10747d4919566a0119e25bfd9030d6213021ecd222bad9e456a7cb3505ee5d3ffc7fe0de5aa1080453565245c3e95cb774df0746f7d4a13b51067bc53b9
+DIST ipython-4.1.2.tar.gz 4953949 SHA256 052f9692a227f285febecec856d749811ac6a20b32c7629b4de31f04ea701692 SHA512 2a28a82cbc5d11cb1f1c88e452f52dbc6b196ac12d46cdec1f35d49e7f97aa8ee5c2a90a6f02f072297c4ef17f84a4454100a4b2594968ec46995c4fd459c09b WHIRLPOOL 1ae1fb4a88d9fd73c93ce096cdb4754d3153e156d87760b48825a2af3ec7eec3d3232b2b0f59f5fce94fb4e14b8c51361781527d9f5320a336ed786fc339567f
diff --git a/dev-python/ipython/ipython-4.1.2.ebuild b/dev-python/ipython/ipython-4.1.2.ebuild
new file mode 100644
index 00000000000..68dc5c2daf5
--- /dev/null
+++ b/dev-python/ipython/ipython-4.1.2.ebuild
@@ -0,0 +1,137 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 python3_{3,4,5} )
+PYTHON_REQ_USE='readline,sqlite,threads(+)'
+
+inherit distutils-r1 eutils virtualx
+
+DESCRIPTION="Advanced interactive shell for Python"
+HOMEPAGE="http://ipython.org/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="doc examples matplotlib mongodb notebook nbconvert qt4 +smp test wxwidgets"
+
+REQUIRED_USE="
+	test? ( doc matplotlib mongodb notebook nbconvert qt4 wxwidgets )
+	doc? ( mongodb )"
+
+CDEPEND="
+	dev-python/decorator[${PYTHON_USEDEP}]
+	dev-python/pexpect[${PYTHON_USEDEP}]
+	dev-python/pickleshare[${PYTHON_USEDEP}]
+	dev-python/pyparsing[${PYTHON_USEDEP}]
+	dev-python/simplegeneric[${PYTHON_USEDEP}]
+	dev-python/traitlets[${PYTHON_USEDEP}]
+	matplotlib? ( dev-python/matplotlib[${PYTHON_USEDEP}] )
+	mongodb? ( <dev-python/pymongo-3[${PYTHON_USEDEP}] )
+	wxwidgets? ( $(python_gen_cond_dep 'dev-python/wxpython:*[${PYTHON_USEDEP}]' python2_7) )"
+
+RDEPEND="${CDEPEND}
+	notebook? (
+		dev-python/notebook[${PYTHON_USEDEP}]
+		dev-python/ipywidgets[${PYTHON_USEDEP}]
+	)
+	nbconvert? ( dev-python/nbconvert[${PYTHON_USEDEP}] )"
+DEPEND="${CDEPEND}
+	>=dev-python/setuptools-18.5[${PYTHON_USEDEP}]
+	test? (
+		app-text/dvipng
+		dev-python/jinja[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep 'dev-python/mock[${PYTHON_USEDEP}]' python2_7)
+		>=dev-python/nose-0.10.1[${PYTHON_USEDEP}]
+		dev-python/pygments[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/sphinx[${PYTHON_USEDEP}]
+		dev-python/testpath[${PYTHON_USEDEP}]
+		>=www-servers/tornado-4.0[${PYTHON_USEDEP}]
+		x11-base/xorg-server[xvfb]
+	)
+	doc? (
+		dev-python/cython[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep 'dev-python/fabric[${PYTHON_USEDEP}]' python2_7)
+		>=dev-python/jsonschema-2.0[${PYTHON_USEDEP}]
+		dev-python/matplotlib[${PYTHON_USEDEP}]
+		>=dev-python/nose-0.10.1[${PYTHON_USEDEP}]
+		dev-python/rpy[${PYTHON_USEDEP}]
+		>=dev-python/sphinx-1.3[${PYTHON_USEDEP}]
+		>=www-servers/tornado-4.0[${PYTHON_USEDEP}]
+	)"
+
+PDEPEND="
+	qt4? ( dev-python/qtconsole )
+	smp? ( dev-python/ipyparallel[${PYTHON_USEDEP}] )"
+
+PATCHES=(
+	"${FILESDIR}"/2.1.0-substitute-files.patch
+	)
+
+DISTUTILS_IN_SOURCE_BUILD=1
+
+python_prepare_all() {
+	# Remove out of date insource files
+	rm IPython/extensions/rmagic.py || die
+
+	# Prevent un-needed download during build
+	if use doc; then
+		sed -e "/^    'sphinx.ext.intersphinx',/d" -i docs/source/conf.py || die
+	fi
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	use doc && emake -C docs html_noapi
+}
+
+python_test() {
+	distutils_install_for_testing
+	# https://github.com/ipython/ipython/issues/8639
+	# Failure of some modules only in python3.4 
+	local fail
+	run_tests() {
+		pushd ${TEST_DIR} > /dev/null || die
+		"${PYTHON}" -m IPython.testing.iptestcontroller --all || fail=1
+		popd > /dev/null || die
+	}
+	VIRTUALX_COMMAND=run_tests virtualmake
+	[[ ${fail} ]] && die "Tests fail with ${EPYTHON}"
+}
+
+python_install() {
+	distutils-r1_python_install
+
+	# Create ipythonX.Y symlinks.
+	# TODO:
+	# 1. do we want them for pypy? No.  pypy has no numpy
+	# 2. handle it in the eclass instead (use _python_ln_rel).
+	# With pypy not an option the dosym becomes unconditional
+	dosym ../lib/python-exec/${EPYTHON}/ipython \
+		/usr/bin/ipython${EPYTHON#python}
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/build/html/. )
+	use examples && local EXAMPLES=( examples/. )
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	optfeature "sympyprinting" dev-python/sympy
+	optfeature "cythonmagic" dev-python/cython
+	optfeature "%lprun magic command" dev-python/line_profiler
+	optfeature "%mprun magic command" dev-python/memory_profiler
+	if use nbconvert; then
+		if ! has_version app-text/pandoc ; then
+			einfo "Node.js will be used to convert notebooks to other formats"
+			einfo "like HTML. Support for that is still experimental. If you"
+			einfo "encounter any problems, please use app-text/pandoc instead."
+		fi
+	fi
+}
-- 
cgit v1.2.1