From ca375fd411897ae66f0691c9f8b257ed364e6e05 Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Micha=C5=82=20G=C3=B3rny?= <mgorny@gentoo.org>
Date: Sun, 18 Dec 2016 14:29:13 +0100
Subject: net-misc/aria2: Bump to 1.30.0

---
 net-misc/aria2/Manifest            |   1 +
 net-misc/aria2/aria2-1.30.0.ebuild | 153 +++++++++++++++++++++++++++++++++++++
 2 files changed, 154 insertions(+)
 create mode 100644 net-misc/aria2/aria2-1.30.0.ebuild

(limited to 'net-misc/aria2')

diff --git a/net-misc/aria2/Manifest b/net-misc/aria2/Manifest
index c5df5c82785..0b729af5e0c 100644
--- a/net-misc/aria2/Manifest
+++ b/net-misc/aria2/Manifest
@@ -7,3 +7,4 @@ DIST aria2-1.26.1.tar.xz 1494864 SHA256 f4e64e9754af5e1c0ee1ee2a50c5fa5acbc18085
 DIST aria2-1.27.1.tar.xz 1489132 SHA256 c09627ef31602cfdfa7c9925a6c3b05fe7d2097d83f42dcfdef68664bd106f08 SHA512 baeb637a231907c3f0f752c46038442745cb2cf224d696727ff567d20f3a9a6a002fca3604a90030dfd4d19ff306fe47d27d37a1e32e55fa0e9cd350c2c624a3 WHIRLPOOL 35620a2057394f8cd21479011f7ad6d663eab1aa230778707b0c5feca46f23a4f80922181fb186464b3b0ed5de4807df5b53e2b9226d110118ce647dc8b2a2f5
 DIST aria2-1.28.0.tar.xz 1495984 SHA256 e0a125a557b9aacf23468374f63215e9b1d6165c990bd8ecb0603cdc1d5d72f0 SHA512 d0a534eadfa7c522fc709a7b54849990e6346263ac9997d15945c0949bee468829b000807fc1ef3a1289fa13eb092461f4c9c7da5b64792078e683bd5942f135 WHIRLPOOL 60110a72accdd9fbde534cad929ed70adff9c837d8cf6be40d1a59c78a22e1ee75318acee1a422b58365567fb38c68f3cabe383f0f02190e54ad2ea88bf5776d
 DIST aria2-1.29.0.tar.xz 1496804 SHA256 1a64d023e75bf61c751609ef0df198596f785f1abc371672a75d5b09bd91c82e SHA512 d48ba8793b664ba663071759f9bbaedd3d557d836db271bef35063733c230c02f6fd59021039a30154c37ecd7b0e793087f8b9226d8a4c9ed01380d6f578c8da WHIRLPOOL 4c41ddcf3230aec01f4086152838bc4ada90127b554f16613f102d97ccb89ade4c9e36a25e8b5c17a9e99478e143fcc2744f9b86f5ae695adf2d837f05f9c6af
+DIST aria2-1.30.0.tar.xz 1497124 SHA256 bf6c5366d11d2a6038c8e19f01f9b874041793aaf317e0206120e3e8c9c431f6 SHA512 8c3deb4b58b9db9e8de52f48f6e863e07743ae4af14e2b2d64ddcac94b6aec16ff8d4f27e7d6076426d597af9e6e0988289f3a1c156796c9d79ee7f60f5edc38 WHIRLPOOL c3613212226c1fe6db20b45dce021441fceaf26970e8773064ef254e3a1272550c9c8e69d2fa677d249a70c853d6ba65c91fa1a42c33009127177b496fcbda0a
diff --git a/net-misc/aria2/aria2-1.30.0.ebuild b/net-misc/aria2/aria2-1.30.0.ebuild
new file mode 100644
index 00000000000..abf92e32545
--- /dev/null
+++ b/net-misc/aria2/aria2-1.30.0.ebuild
@@ -0,0 +1,153 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="6"
+
+inherit bash-completion-r1
+
+DESCRIPTION="A download utility with segmented downloading with BitTorrent support"
+HOMEPAGE="https://aria2.github.io/"
+SRC_URI="https://github.com/aria2/${PN}/releases/download/release-${PV}/${P}.tar.xz"
+
+LICENSE="GPL-2"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
+SLOT="0"
+IUSE="adns bittorrent +gnutls jemalloc libuv +libxml2 metalink +nettle nls sqlite scripts ssh ssl tcmalloc test xmlrpc"
+
+CDEPEND="sys-libs/zlib:0=
+	ssl? (
+		app-misc/ca-certificates
+		gnutls? ( >=net-libs/gnutls-1.2.9:0= )
+		!gnutls? ( dev-libs/openssl:0= ) )
+	adns? ( >=net-dns/c-ares-1.5.0:0= )
+	bittorrent? (
+		ssl? (
+			gnutls? (
+				nettle? ( >=dev-libs/nettle-2.4:0=[gmp] >=dev-libs/gmp-5:0= )
+				!nettle? ( >=dev-libs/libgcrypt-1.2.2:0= ) ) )
+		!ssl? (
+			nettle? ( >=dev-libs/nettle-2.4:0=[gmp] >=dev-libs/gmp-5:0= )
+			!nettle? ( >=dev-libs/libgcrypt-1.2.2:0= ) ) )
+	jemalloc? ( dev-libs/jemalloc )
+	libuv? ( dev-libs/libuv:0= )
+	metalink? (
+		libxml2? ( >=dev-libs/libxml2-2.6.26:2= )
+		!libxml2? ( dev-libs/expat:0= ) )
+	sqlite? ( dev-db/sqlite:3= )
+	ssh? ( net-libs/libssh2:= )
+	tcmalloc? ( dev-util/google-perftools )
+	xmlrpc? (
+		libxml2? ( >=dev-libs/libxml2-2.6.26:2= )
+		!libxml2? ( dev-libs/expat:0= ) )"
+
+DEPEND="${CDEPEND}
+	app-arch/xz-utils
+	virtual/pkgconfig
+	nls? ( sys-devel/gettext )
+	test? ( >=dev-util/cppunit-1.12.0:0 )"
+RDEPEND="${CDEPEND}
+	nls? ( virtual/libiconv virtual/libintl )
+	scripts? ( dev-lang/ruby )"
+
+# xmlrpc has no explicit switch, it's turned out by any XML library
+# so metalink implicitly forces it on
+REQUIRED_USE="?? ( jemalloc tcmalloc )
+	metalink? ( xmlrpc )"
+RESTRICT="!test? ( test )"
+
+pkg_setup() {
+	if use scripts && ! use xmlrpc; then
+		ewarn "Please note that you may need to enable USE=xmlrpc to run the aria2rpc"
+		ewarn "and aria2mon scripts against the local aria2."
+	fi
+}
+
+src_prepare() {
+	default
+	sed -i -e "s|/tmp|${T}|" test/*.cc test/*.txt || die "sed failed"
+}
+
+src_configure() {
+	local myconf=(
+		# threads, epoll: check for best portability
+
+		# do not try to compile and run a test LIBXML program
+		--disable-xmltest
+		# enable the shared library
+		--enable-libaria2
+		# zlib should always be available anyway
+		--with-libz
+		--with-ca-bundle="${EPREFIX}/etc/ssl/certs/ca-certificates.crt"
+
+		# optional features
+		$(use_enable bittorrent)
+		$(use_enable metalink)
+		$(use_enable nls)
+		$(use_with adns libcares)
+		$(use_with jemalloc)
+		$(use_with libuv)
+		$(use_with sqlite sqlite3)
+		$(use_with ssh libssh2)
+		$(use_with tcmalloc)
+	)
+
+	# SSL := gnutls / openssl
+	# USE=ssl
+	#  + USE=gnutls -> gnutls
+	#  + USE=-gnutls -> openssl
+
+	if use ssl; then
+		myconf+=( $(use_with gnutls) $(use_with !gnutls openssl) )
+	else
+		myconf+=( --without-gnutls --without-openssl )
+	fi
+
+	# message-digest := nettle / gcrypt / openssl
+	# bignum := nettle+gmp / gcrypt / openssl
+	# bittorrent := message-digest + bignum
+	# USE=bittorrent
+	#  + USE=(ssl -gnutls) -> openssl
+	#  + USE=nettle -> nettle+gmp
+	#  + USE=-nettle -> gcrypt
+
+	if use !bittorrent || use ssl && use !gnutls; then
+		myconf+=( --without-libgcrypt --without-libnettle --without-libgmp )
+	else
+		myconf+=( $(use_with !nettle libgcrypt)
+			$(use_with nettle libnettle) $(use_with nettle libgmp) )
+	fi
+
+	# metalink+xmlrpc := libxml2 / expat
+	# USE=(metalink || xmlrpc)
+	#  + USE=libxml2 -> libxml2
+	#  + USE=-libxml2 -> expat
+
+	if use metalink || use xmlrpc; then
+		myconf+=( $(use_with !libxml2 libexpat) $(use_with libxml2) )
+	else
+		myconf+=( --without-libexpat --without-libxml2 )
+	fi
+
+	# Note:
+	# - always enable gzip/http compression since zlib should always be available anyway
+	# - always enable epoll since we can assume kernel 2.6.x
+	# - other options for threads: solaris, pth, win32
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	default
+	rm -rf "${D}"/usr/share/doc/aria2 \
+		"${D}"/usr/share/doc/${PF}/README{,.html}
+
+	dobashcomp doc/bash_completion/aria2c
+	use scripts && dobin doc/xmlrpc/aria2{mon,rpc}
+}
+
+pkg_postinst() {
+	if use xmlrpc; then
+		elog "If you would like to use the additional aria2mon and aria2rpc tools,"
+		elog "you need to have \033[1mdev-lang/ruby\033[0m installed."
+	fi
+}
-- 
cgit v1.2.1