From f5729bf9f598b341be093fe6e94499651f18c24a Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Micha=C5=82=20G=C3=B3rny?= <mgorny@gentoo.org>
Date: Sat, 3 Sep 2016 13:41:58 +0200
Subject: net-misc/aria2: Version bump to 1.26.1 (assertion fix)

---
 net-misc/aria2/Manifest            |   1 +
 net-misc/aria2/aria2-1.26.1.ebuild | 150 +++++++++++++++++++++++++++++++++++++
 2 files changed, 151 insertions(+)
 create mode 100644 net-misc/aria2/aria2-1.26.1.ebuild

(limited to 'net-misc/aria2')

diff --git a/net-misc/aria2/Manifest b/net-misc/aria2/Manifest
index 8280284c46e..c043b5a29ab 100644
--- a/net-misc/aria2/Manifest
+++ b/net-misc/aria2/Manifest
@@ -3,3 +3,4 @@ DIST aria2-1.23.0.tar.xz 1493704 SHA256 585185866415bf1120e4bf0a484e7dfec2e9e7c5
 DIST aria2-1.24.0.tar.xz 1495632 SHA256 35a496d2704ffb07e0b0dcac16c6d9b2854327967f984218517403d187f7bf37 SHA512 3e7f3fc2cd30edb5813b0d0fe6742671000730aa8d7e41e5396ab673912b8492885273de740985517b4a16efccedb1bdffb9bfdc235aa0d5fc31d2b547ae61e7 WHIRLPOOL 31a22233c5aacfaf8ee93da4bc13af0138ab6bc6eec6a458cb846834d61ddf2f1082a69a1eb24ee8feaad65d426a8fd4c235ffd886dbee44fb8749ecf79c3f0e
 DIST aria2-1.25.0.tar.xz 1493880 SHA256 ff89eb4c76cfc816a6f5abc7dfd416cc3f339e7d02c761f822fa965a18cf0d35 SHA512 d7a58ff895a6c2adfb80ef3a21419ebb18a5539290d11df4a8023dc46289f71a80a07ce15b4f146c1640fb4065f48d38c0a065437f5a36098c99e3350c4993ab WHIRLPOOL 783bafee91742d5f093a52bb3a792b55c37f920faff386ec80589f203a3e2df291efd83c8f3c9fa15bd5b982ca4b93bd25c8af227e68fe710d6d797a922aec21
 DIST aria2-1.26.0.tar.xz 1496396 SHA256 c828f3375e9ab251239747fbbbf747e5027339080b9fdec29ac746a0b8c6088d SHA512 f87875c0740df054f44018431cff6e215f48a2458278be740b4cd7baa5723e8ed52215ea8c7c54944324f942bfe5c0ca7a532a9eb39eca3428a2f2d58e0ca0f0 WHIRLPOOL 4bfe87985775c547d86ad99ae1315e45c466b5ba00ea49e4a2b851621ae332833e55f86af764f96e3b408302ad8eccdeb00313b34b95a9e90f86503569f3cf88
+DIST aria2-1.26.1.tar.xz 1494864 SHA256 f4e64e9754af5e1c0ee1ee2a50c5fa5acbc180855909209c2ce0111e86c9a801 SHA512 1a96451ed72a557cddd605f2362c40b0db40878f3a40ce6898c95257178a2c04d5570354ac28dd4d451ed2931eb6bc86fb9addab6b0fd60857d026aae691e683 WHIRLPOOL 2e551bbd1af6d14ba396b26ee650dab7b89f258ca9cf84b90e09365fef80f944933fa1c0b1cf1bc5e3154c780b9fa3b08427c4efb9e4eded6c6c5559024a002b
diff --git a/net-misc/aria2/aria2-1.26.1.ebuild b/net-misc/aria2/aria2-1.26.1.ebuild
new file mode 100644
index 00000000000..38d2f5320aa
--- /dev/null
+++ b/net-misc/aria2/aria2-1.26.1.ebuild
@@ -0,0 +1,150 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="6"
+
+inherit bash-completion-r1
+
+DESCRIPTION="A download utility with segmented downloading with BitTorrent support"
+HOMEPAGE="http://aria2.sourceforge.net/"
+SRC_URI="https://github.com/tatsuhiro-t/${PN}/releases/download/release-${PV}/${P}.tar.xz"
+
+LICENSE="GPL-2"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
+SLOT="0"
+IUSE="adns bittorrent +gnutls jemalloc libuv +libxml2 metalink +nettle nls sqlite scripts ssh ssl tcmalloc test xmlrpc"
+
+CDEPEND="sys-libs/zlib:0=
+	ssl? (
+		app-misc/ca-certificates
+		gnutls? ( >=net-libs/gnutls-1.2.9:0= )
+		!gnutls? ( dev-libs/openssl:0= ) )
+	adns? ( >=net-dns/c-ares-1.5.0:0= )
+	bittorrent? (
+		ssl? (
+			gnutls? (
+				nettle? ( >=dev-libs/nettle-2.4:0=[gmp] >=dev-libs/gmp-5:0= )
+				!nettle? ( >=dev-libs/libgcrypt-1.2.2:0= ) ) )
+		!ssl? (
+			nettle? ( >=dev-libs/nettle-2.4:0=[gmp] >=dev-libs/gmp-5:0= )
+			!nettle? ( >=dev-libs/libgcrypt-1.2.2:0= ) ) )
+	jemalloc? ( dev-libs/jemalloc )
+	libuv? ( dev-libs/libuv:0= )
+	metalink? (
+		libxml2? ( >=dev-libs/libxml2-2.6.26:2= )
+		!libxml2? ( dev-libs/expat:0= ) )
+	sqlite? ( dev-db/sqlite:3= )
+	ssh? ( net-libs/libssh2:= )
+	tcmalloc? ( dev-util/google-perftools )
+	xmlrpc? (
+		libxml2? ( >=dev-libs/libxml2-2.6.26:2= )
+		!libxml2? ( dev-libs/expat:0= ) )"
+
+DEPEND="${CDEPEND}
+	app-arch/xz-utils
+	virtual/pkgconfig
+	nls? ( sys-devel/gettext )
+	test? ( >=dev-util/cppunit-1.12.0:0 )"
+RDEPEND="${CDEPEND}
+	nls? ( virtual/libiconv virtual/libintl )
+	scripts? ( dev-lang/ruby )"
+
+REQUIRED_USE="jemalloc? ( !tcmalloc )
+	tcmalloc? ( !jemalloc )"
+RESTRICT="!test? ( test )"
+
+pkg_setup() {
+	if use scripts && use !xmlrpc && use !metalink; then
+		ewarn "Please note that you may need to enable USE=xmlrpc to run the aria2rpc"
+		ewarn "and aria2mon scripts against the local aria2."
+	fi
+}
+
+src_prepare() {
+	default
+	sed -i -e "s|/tmp|${T}|" test/*.cc test/*.txt || die "sed failed"
+}
+
+src_configure() {
+	local myconf=(
+		# threads, epoll: check for best portability
+
+		# do not try to compile and run a test LIBXML program
+		--disable-xmltest
+		# enable the shared library
+		--enable-libaria2
+		# zlib should always be available anyway
+		--with-libz
+		--with-ca-bundle="${EPREFIX}/etc/ssl/certs/ca-certificates.crt"
+
+		# optional features
+		$(use_enable bittorrent)
+		$(use_enable metalink)
+		$(use_enable nls)
+		$(use_with sqlite sqlite3)
+		$(use_with adns libcares)
+		$(use_with libuv)
+		$(use_with jemalloc)
+		$(use_with tcmalloc)
+	)
+
+	# SSL := gnutls / openssl
+	# USE=ssl
+	#  + USE=gnutls -> gnutls
+	#  + USE=-gnutls -> openssl
+
+	if use ssl; then
+		myconf+=( $(use_with gnutls) $(use_with !gnutls openssl) )
+	else
+		myconf+=( --without-gnutls --without-openssl )
+	fi
+
+	# message-digest := nettle / gcrypt / openssl
+	# bignum := nettle+gmp / gcrypt / openssl
+	# bittorrent := message-digest + bignum
+	# USE=bittorrent
+	#  + USE=(ssl -gnutls) -> openssl
+	#  + USE=nettle -> nettle+gmp
+	#  + USE=-nettle -> gcrypt
+
+	if use !bittorrent || use ssl && use !gnutls; then
+		myconf+=( --without-libgcrypt --without-libnettle --without-libgmp )
+	else
+		myconf+=( $(use_with !nettle libgcrypt)
+			$(use_with nettle libnettle) $(use_with nettle libgmp) )
+	fi
+
+	# metalink+xmlrpc := libxml2 / expat
+	# USE=(metalink || xmlrpc)
+	#  + USE=libxml2 -> libxml2
+	#  + USE=-libxml2 -> expat
+
+	if use metalink || use xmlrpc; then
+		myconf+=( $(use_with !libxml2 libexpat) $(use_with libxml2) )
+	else
+		myconf+=( --without-libexpat --without-libxml2 )
+	fi
+
+	# Note:
+	# - always enable gzip/http compression since zlib should always be available anyway
+	# - always enable epoll since we can assume kernel 2.6.x
+	# - other options for threads: solaris, pth, win32
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	default
+	rm -rf "${D}"/usr/share/doc/aria2 \
+		"${D}"/usr/share/doc/${PF}/README{,.html}
+
+	dobashcomp doc/bash_completion/aria2c
+	use scripts && dobin doc/xmlrpc/aria2{mon,rpc}
+}
+
+pkg_postinst() {
+	if use xmlrpc || use metalink; then
+		elog "If you would like to use the additional aria2mon and aria2rpc tools,"
+		elog "you need to have \033[1mdev-lang/ruby\033[0m installed."
+	fi
+}
-- 
cgit v1.2.1