From 0b6c17dbf8ae8687d75da5c4db9e910bbeb67eb5 Mon Sep 17 00:00:00 2001
From: Gilles Dartiguelongue <eva@gentoo.org>
Date: Mon, 21 Aug 2017 00:43:28 +0200
Subject: net-voip/telepathy-haze: port to unsplit twisted dependencies, bug
 #605112

Bump to EAPI=6. Fix python-*-r1 usage for unittests. Update homepage.
Re-enable unittests. Add missing dependency on pidgin with dbus
support enabled.

Package-Manager: Portage-2.3.8, Repoman-2.3.3
---
 .../telepathy-haze/telepathy-haze-0.8.0-r2.ebuild  | 56 ++++++++++++++++++++++
 1 file changed, 56 insertions(+)
 create mode 100644 net-voip/telepathy-haze/telepathy-haze-0.8.0-r2.ebuild

(limited to 'net-voip/telepathy-haze')

diff --git a/net-voip/telepathy-haze/telepathy-haze-0.8.0-r2.ebuild b/net-voip/telepathy-haze/telepathy-haze-0.8.0-r2.ebuild
new file mode 100644
index 00000000000..838d5918129
--- /dev/null
+++ b/net-voip/telepathy-haze/telepathy-haze-0.8.0-r2.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 )
+
+inherit python-any-r1
+
+DESCRIPTION="Telepathy connection manager providing libpurple supported protocols"
+HOMEPAGE="https://telepathy.freedesktop.org/"
+SRC_URI="https://telepathy.freedesktop.org/releases/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="test"
+
+RDEPEND="
+	>=net-im/pidgin-2.7[dbus]
+	>=net-libs/telepathy-glib-0.15.1
+	>=dev-libs/glib-2.30:2
+	>=dev-libs/dbus-glib-0.73
+"
+DEPEND="${RDEPEND}
+	${PYTHON_DEPS}
+	dev-libs/libxslt
+	virtual/pkgconfig
+	test? (
+		|| (
+			$(python_gen_any_dep 'dev-python/twisted[${PYTHON_USEDEP}]')
+			$(python_gen_any_dep 'dev-python/twisted-words[${PYTHON_USEDEP}]')
+		)
+	)
+"
+
+PATCHES=(
+	# contact-list: Don't crash if a contact is already in the roster
+	# (fixed in next version)
+	"${FILESDIR}"/${P}-crash.patch
+
+	# Fix compat with newer pidgin versions, bug #572296
+	"${FILESDIR}"/${P}-pidgin-2.10.12-compat.patch
+)
+
+python_check_deps() {
+	use test \
+		&& { has_version "dev-python/twisted[${PYTHON_USEDEP}]" \
+			|| has_version "dev-python/twisted-words[${PYTHON_USEDEP}]"; }
+}
+
+src_prepare() {
+	default
+	# Disable failing test
+	sed -i 's|simple-caps.py||' -i tests/twisted/Makefile.{am,in} || die
+}
-- 
cgit v1.2.1