From 926eef459172d839e157412df307229d7fc5c12c Mon Sep 17 00:00:00 2001
From: Julian Ospald <hasufell@gentoo.org>
Date: Tue, 11 Aug 2015 01:22:41 +0200
Subject: x11-misc/gpaste: version bump to 3.16.2.1

This is totally untested, added with lots of good faith, since
I don't want to update my glib just yet.
---
 x11-misc/gpaste/Manifest               |  1 +
 x11-misc/gpaste/gpaste-3.16.2.1.ebuild | 81 ++++++++++++++++++++++++++++++++++
 2 files changed, 82 insertions(+)
 create mode 100644 x11-misc/gpaste/gpaste-3.16.2.1.ebuild

(limited to 'x11-misc')

diff --git a/x11-misc/gpaste/Manifest b/x11-misc/gpaste/Manifest
index 372affdccaf..72abf393008 100644
--- a/x11-misc/gpaste/Manifest
+++ b/x11-misc/gpaste/Manifest
@@ -1 +1,2 @@
 DIST gpaste-3.14.tar.gz 146295 SHA256 55d6547aec756fc55f88adbebd6685147e23cac5683308d2e424c2982ce2dbbd SHA512 ffafa6ef19a65af5cea2a74a6c7ea6e33a6097d4aeae6c78628cfadf2e2fde1ae30eb2bb5723b4f58c225ac68a2db5f3f114ffa9da7544b7765bc5fe033d824f WHIRLPOOL 4c178c1dc5e4f905bdf406c4ac23b8e74bfba60d9f0c1a93978153deedc1a8eaba989fcb453ace1a16aecdf4effd0d8bc12a03ac28b3c09a427a10151eb032ab
+DIST gpaste-3.16.2.1.tar.gz 144459 SHA256 f1bcb6f67f43b61754cc7b192ea352cea0c04812d677d0d30ebaaafa6f6ae58d SHA512 55512b9ca01099198e8cc718cc19e5176db9809e95d3b5777d7ce550d9a717e829390056bd94b24d18c63651db01e62105839ae0364f3882d6102943fc3dd015 WHIRLPOOL 2c232c08efb7c159329c68dadfe2493d5e4e503d7bcea105f9eaccbad49c4bbd978113ca81882c6de89dac4cbdedc9d42f05c7709e51ab5d71e2279f0852d17d
diff --git a/x11-misc/gpaste/gpaste-3.16.2.1.ebuild b/x11-misc/gpaste/gpaste-3.16.2.1.ebuild
new file mode 100644
index 00000000000..47b2d4f6ae8
--- /dev/null
+++ b/x11-misc/gpaste/gpaste-3.16.2.1.ebuild
@@ -0,0 +1,81 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+VALA_USE_DEPEND="vapigen"
+
+inherit eutils autotools gnome2-utils vala vcs-snapshot
+
+DESCRIPTION="Clipboard management system"
+HOMEPAGE="https://github.com/Keruspe/GPaste"
+SRC_URI="https://github.com/Keruspe/GPaste/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+applet gnome vala"
+
+CDEPEND="
+	dev-util/appdata-tools
+	>=dev-libs/glib-2.44:2
+	>=dev-libs/gobject-introspection-1.44.0
+	sys-apps/dbus
+	>=x11-libs/gdk-pixbuf-2.26:2
+	>=x11-libs/gtk+-3.16:3
+	x11-libs/libX11
+	x11-libs/libXi
+	gnome? (
+		gnome-base/gnome-control-center:2
+		media-libs/clutter
+		x11-libs/pango
+	)
+"
+RDEPEND="${CDEPEND}
+	gnome? (
+		gnome-base/gnome-shell
+	)
+"
+DEPEND="${CDEPEND}
+	dev-util/intltool
+	virtual/pkgconfig
+	vala? ( $(vala_depend) )
+"
+
+src_prepare() {
+	eautoreconf
+	intltoolize --force --automake || die "intltoolize error"
+	vala_src_prepare
+
+	if ! use gnome ; then
+		echo "" > data/control-center.mk || die
+	fi
+}
+
+src_configure() {
+	econf \
+		$(use_enable vala) \
+		$(use_enable applet) \
+		--disable-unity \
+		$(use_enable gnome gnome-shell-extension) \
+		--disable-static \
+		--disable-schemas-compile
+}
+
+src_install() {
+	default
+	prune_libtool_files
+}
+
+pkg_preinst() {
+	gnome2_schemas_savelist
+}
+
+pkg_postinst() {
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	gnome2_schemas_update
+}
-- 
cgit v1.2.1