games-action/teeworlds: Version bump to 0.6.4

Gentoo-Bug: https://bugs.gentoo.org/600178

Package-Manager: Portage-2.3.3, Repoman-2.3.1
Closes: https://github.com/gentoo/gentoo/pull/4400

9 files changed, 133 insertions, 8 deletions

diff --git a/games-action/teeworlds/Manifest b/games-action/teeworlds/Manifest
index 9829eb71349..74b45ac09c5 100644
--- a/games-action/teeworlds/Manifest
+++ b/games-action/teeworlds/Manifest
@@ -1 +1,2 @@
 DIST teeworlds-0.6.3-src.tar.gz 13101446 SHA256 490ee7c372898761c609af8d7b0c6bd55942c6c6fcd7f361eefa00abfc70077b SHA512 0c7ef6ca59e4b49f9e208f39e8b0edd76965d67848008af3a223cb7615a6c62ff433d3113f733ae4dafc364baf522d2f56255e058d26d9f5c48071cdde41526d WHIRLPOOL dc501bb9a2f4c3971ad063102a55cc70633857e3052f3a349d032dd8e92ea05f6138c62e9775b743b38dc3a56366d9920850b5a7ffbf6913ed73536a5cacdff4
+DIST teeworlds-0.6.4-src.tar.gz 8771622 SHA256 c261d19ebb00b5451faa2ceb4a7ca945cad2add48b06046eb43b40ccc9fd98e2 SHA512 7546ee358a2126339f6c727bb7b5f49009a8fad0b5e77a796202cba4d8fc5dfcaf79b7e65151d85fead2a70ad61ef3e1888b8c07fe0206f87575d5dd8c9f91ce WHIRLPOOL ea45aeb1eeef511e38b19e051dc575b7506dba002ed27a3850aabbb9bfac9a0530bc033d3428ede75a0081c054a573a91c0c942cf49477645674ad5d4aa28764
diff --git a/games-action/teeworlds/files/0.6.3/01-use-system-wavpack.patch b/games-action/teeworlds/files/0.6/01-use-system-wavpack.patch
index 4a11a866511..4a11a866511 100644
--- a/games-action/teeworlds/files/0.6.3/01-use-system-wavpack.patch
+++ b/games-action/teeworlds/files/0.6/01-use-system-wavpack.patch
diff --git a/games-action/teeworlds/files/0.6.3/02-fixed-wavpack-sound-loading.patch b/games-action/teeworlds/files/0.6/02-fixed-wavpack-sound-loading.patch
index e207a4a354b..e207a4a354b 100644
--- a/games-action/teeworlds/files/0.6.3/02-fixed-wavpack-sound-loading.patch
+++ b/games-action/teeworlds/files/0.6/02-fixed-wavpack-sound-loading.patch
diff --git a/games-action/teeworlds/files/0.6.3/03-use-system-pnglite.patch b/games-action/teeworlds/files/0.6/03-use-system-pnglite.patch
index 81c3d915316..81c3d915316 100644
--- a/games-action/teeworlds/files/0.6.3/03-use-system-pnglite.patch
+++ b/games-action/teeworlds/files/0.6/03-use-system-pnglite.patch
diff --git a/games-action/teeworlds/files/0.6.3/04-dedicated.patch b/games-action/teeworlds/files/0.6/04-dedicated.patch
index fc61b71283b..fc61b71283b 100644
--- a/games-action/teeworlds/files/0.6.3/04-dedicated.patch
+++ b/games-action/teeworlds/files/0.6/04-dedicated.patch
diff --git a/games-action/teeworlds/files/0.6.3/05-cc-cflags.patch b/games-action/teeworlds/files/0.6/05-cc-cflags.patch
index dec6b8d306f..dec6b8d306f 100644
--- a/games-action/teeworlds/files/0.6.3/05-cc-cflags.patch
+++ b/games-action/teeworlds/files/0.6/05-cc-cflags.patch
diff --git a/games-action/teeworlds/teeworlds-0.6.3-r1.ebuild b/games-action/teeworlds/teeworlds-0.6.3-r1.ebuild
index fe0ccfa211b..c7affb67818 100644
--- a/games-action/teeworlds/teeworlds-0.6.3-r1.ebuild
+++ b/games-action/teeworlds/teeworlds-0.6.3-r1.ebuild
@@ -3,7 +3,7 @@
 
 EAPI=6
 PYTHON_COMPAT=( python2_7 )
-inherit eutils multiprocessing python-any-r1 toolchain-funcs
+inherit eutils multiprocessing python-any-r1 toolchain-funcs versionator
 
 REVISION="b177-r50edfd37"
 
@@ -32,13 +32,14 @@ DEPEND="${RDEPEND}
 	~dev-util/bam-0.4.0"
 
 S=${WORKDIR}/${P}-src
+MY_PV=$(get_version_component_range 1-2)
 
 PATCHES=(
-	"${FILESDIR}/${PV}/01-use-system-wavpack.patch"
-	"${FILESDIR}/${PV}/02-fixed-wavpack-sound-loading.patch"
-	"${FILESDIR}/${PV}/03-use-system-pnglite.patch"
-	"${FILESDIR}/${PV}/04-dedicated.patch"
-	"${FILESDIR}/${PV}/05-cc-cflags.patch"
+	"${FILESDIR}/${MY_PV}/01-use-system-wavpack.patch"
+	"${FILESDIR}/${MY_PV}/02-fixed-wavpack-sound-loading.patch"
+	"${FILESDIR}/${MY_PV}/03-use-system-pnglite.patch"
+	"${FILESDIR}/${MY_PV}/04-dedicated.patch"
+	"${FILESDIR}/${MY_PV}/05-cc-cflags.patch"
 )
 
 pkg_setup() {
diff --git a/games-action/teeworlds/teeworlds-0.6.3.ebuild b/games-action/teeworlds/teeworlds-0.6.3.ebuild
index 6ec2bfd5c05..791c9d00e07 100644
--- a/games-action/teeworlds/teeworlds-0.6.3.ebuild
+++ b/games-action/teeworlds/teeworlds-0.6.3.ebuild
@@ -3,7 +3,7 @@
 
 EAPI=5
 PYTHON_COMPAT=( python2_7 )
-inherit eutils multiprocessing python-any-r1 toolchain-funcs games
+inherit eutils multiprocessing python-any-r1 toolchain-funcs games versionator
 
 REVISION="b177-r50edfd37"
 
@@ -31,6 +31,7 @@ DEPEND="${RDEPEND}
 	~dev-util/bam-0.4.0"
 
 S=${WORKDIR}/${P}-src
+MY_PV=$(get_version_component_range 1-2)
 
 pkg_setup() {
 	python-any-r1_pkg_setup
@@ -41,7 +42,7 @@ src_prepare() {
 	rm -r src/engine/external/* || die
 
 	# 01 & 02 from pull request: https://github.com/oy/teeworlds/pull/493
-	EPATCH_SOURCE="${FILESDIR}/${PV}" EPATCH_SUFFIX="patch" EPATCH_FORCE="yes" \
+	EPATCH_SOURCE="${FILESDIR}/${MY_PV}" EPATCH_SUFFIX="patch" EPATCH_FORCE="yes" \
 		epatch
 
 	cat <<- __EOF__ > "${S}/gentoo.lua"
diff --git a/games-action/teeworlds/teeworlds-0.6.4.ebuild b/games-action/teeworlds/teeworlds-0.6.4.ebuild
new file mode 100644
index 00000000000..dc1a0d9c2f2
--- /dev/null
+++ b/games-action/teeworlds/teeworlds-0.6.4.ebuild
@@ -0,0 +1,122 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python2_7 )
+inherit eutils multiprocessing python-any-r1 toolchain-funcs versionator
+
+REVISION="b177-rff25472"
+
+DESCRIPTION="Online multi-player platform 2D shooter"
+HOMEPAGE="http://www.teeworlds.com/"
+SRC_URI="https://downloads.teeworlds.com/${P}-src.tar.gz"
+
+LICENSE="ZLIB"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="debug dedicated"
+
+RDEPEND="
+	!dedicated? (
+		app-arch/bzip2
+		media-libs/freetype
+		media-libs/libsdl[X,sound,opengl,video]
+		media-libs/pnglite
+		media-sound/wavpack
+		virtual/glu
+		virtual/opengl
+		x11-libs/libX11 )
+	sys-libs/zlib"
+DEPEND="${RDEPEND}
+	${PYTHON_DEPS}
+	~dev-util/bam-0.4.0"
+
+S=${WORKDIR}/${P}-src
+MY_PV=$(get_version_component_range 1-2)
+
+PATCHES=(
+	"${FILESDIR}/${MY_PV}/01-use-system-wavpack.patch"
+	"${FILESDIR}/${MY_PV}/02-fixed-wavpack-sound-loading.patch"
+	"${FILESDIR}/${MY_PV}/03-use-system-pnglite.patch"
+	"${FILESDIR}/${MY_PV}/04-dedicated.patch"
+	"${FILESDIR}/${MY_PV}/05-cc-cflags.patch"
+)
+
+pkg_setup() {
+	python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+
+	rm -r src/engine/external/* || die
+
+	cat <<- __EOF__ > "${S}/gentoo.lua"
+		function addSettings(settings)
+			print("Adding Gentoo settings")
+			settings.optimize = 0
+			settings.cc.exe_c = "$(tc-getCC)"
+			settings.cc.exe_cxx = "$(tc-getCXX)"
+			settings.cc.flags_c:Add("${CFLAGS}")
+			settings.cc.flags_cxx:Add("${CXXFLAGS}")
+			settings.link.exe = "$(tc-getCXX)"
+			settings.link.flags:Add("${LDFLAGS}")
+		end
+	__EOF__
+
+	sed -i \
+		-e "s#/usr/share/games/teeworlds/data#/usr/share/${PN}/data#" \
+		src/engine/shared/storage.cpp || die
+}
+
+src_configure() {
+	bam -v config || die
+}
+
+src_compile() {
+	local myopt
+
+	if use debug; then
+		myopt=" server_debug"
+	else
+		myopt=" server_release"
+	fi
+	if ! use dedicated; then
+		if use debug; then
+			myopt+=" client_debug"
+		else
+			myopt+=" client_release"
+		fi
+	fi
+
+	bam -v -a -j $(makeopts_jobs) ${myopt} || die
+}
+
+src_install() {
+	if use debug; then
+		newbin ${PN}_srv_d ${PN}_srv
+	else
+		dobin ${PN}_srv
+	fi
+	if ! use dedicated; then
+		if use debug; then
+			newbin ${PN}_d ${PN}
+		else
+			dobin ${PN}
+		fi
+
+		doicon "${FILESDIR}"/${PN}.xpm
+		make_desktop_entry ${PN} Teeworlds
+
+		insinto /usr/share/${PN}/data
+		doins -r data/*
+	else
+		insinto /usr/share/${PN}/data/maps
+		doins -r data/maps/*
+	fi
+	newinitd "${FILESDIR}"/${PN}-init.d ${PN}
+	insinto "/etc/${PN}"
+	doins "${FILESDIR}"/teeworlds_srv.cfg
+
+	dodoc readme.txt
+}