Merge remote-tracking branch 'github/pr/393'.

20 files changed, 743 insertions, 3 deletions

diff --git a/lxqt-base/liblxqt/liblxqt-0.10.0.ebuild b/lxqt-base/liblxqt/liblxqt-0.10.0.ebuild
new file mode 100644
index 00000000000..5c17072bc73
--- /dev/null
+++ b/lxqt-base/liblxqt/liblxqt-0.10.0.ebuild
@@ -0,0 +1,40 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+inherit cmake-utils
+
+DESCRIPTION="Common base library for the LXQt desktop environment"
+HOMEPAGE="http://lxqt.org/"
+
+if [[ ${PV} = *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="git://git.lxde.org/git/lxde/${PN}.git"
+else
+	SRC_URI="https://downloads.lxqt.org/lxqt/${PV}/${P}.tar.xz"
+	KEYWORDS="~amd64   ~x86"
+fi
+
+LICENSE="GPL-2 LGPL-2.1+"
+SLOT="0"
+
+RDEPEND=">=dev-libs/libqtxdg-1.0.0
+	dev-qt/qtcore:5
+	dev-qt/qtdbus:5
+	dev-qt/qtgui:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtx11extras:5
+	dev-qt/qtxml:5
+	kde-frameworks/kwindowsystem:5[X]
+"
+DEPEND="${RDEPEND}
+	dev-qt/linguist-tools:5
+"
+
+pkg_pretend() {
+	if [[ ${MERGE_TYPE} != binary ]]; then
+		[[ $(gcc-version) < 4.8 ]] && \
+		die 'The active compiler needs to be gcc 4.8 (or newer)'
+	fi
+}
diff --git a/lxqt-base/libsysstat/libsysstat-0.3.1.ebuild b/lxqt-base/libsysstat/libsysstat-0.3.1.ebuild
new file mode 100644
index 00000000000..c8203a8c715
--- /dev/null
+++ b/lxqt-base/libsysstat/libsysstat-0.3.1.ebuild
@@ -0,0 +1,27 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+inherit cmake-utils
+
+DESCRIPTION="A Qt-based interface to system statistics"
+HOMEPAGE="http://lxqt.org/"
+
+if [[ ${PV} = *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="git://git.lxde.org/git/lxde/${PN}.git"
+else
+	SRC_URI="https://downloads.lxqt.org/${PN}/${PV}/${P}.tar.xz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+fi
+
+LICENSE="GPL-2 LGPL-2.1+"
+SLOT="0"
+
+RDEPEND="
+	dev-qt/qtcore:5
+"
+DEPEND="${RDEPEND}
+	dev-qt/linguist-tools:5
+"
diff --git a/lxqt-base/lxqt-about/lxqt-about-0.10.0.ebuild b/lxqt-base/lxqt-about/lxqt-about-0.10.0.ebuild
new file mode 100644
index 00000000000..dfcda83abf9
--- /dev/null
+++ b/lxqt-base/lxqt-about/lxqt-about-0.10.0.ebuild
@@ -0,0 +1,31 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+inherit cmake-utils
+
+DESCRIPTION="LXQt about dialog"
+HOMEPAGE="http://lxqt.org/"
+
+if [[ ${PV} = *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="git://git.lxde.org/git/lxde/${PN}.git"
+else
+	SRC_URI="https://downloads.lxqt.org/lxqt/${PV}/${P}.tar.xz"
+	KEYWORDS="~amd64   ~x86"
+fi
+
+LICENSE="GPL-2 LGPL-2.1+"
+SLOT="0"
+
+DEPEND="
+	dev-qt/qtcore:5
+	dev-qt/qtdbus:5
+	dev-qt/qtgui:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtx11extras:5
+	dev-qt/qtxml:5
+	~lxqt-base/liblxqt-${PV}
+"
+RDEPEND="${DEPEND}"
diff --git a/lxqt-base/lxqt-admin/lxqt-admin-0.10.0.ebuild b/lxqt-base/lxqt-admin/lxqt-admin-0.10.0.ebuild
new file mode 100644
index 00000000000..2f2453f0c8d
--- /dev/null
+++ b/lxqt-base/lxqt-admin/lxqt-admin-0.10.0.ebuild
@@ -0,0 +1,35 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+inherit cmake-utils
+
+DESCRIPTION="LXQt system administration tool"
+HOMEPAGE="http://lxqt.org/"
+
+if [[ ${PV} = *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="git://git.lxde.org/git/lxde/${PN}.git"
+else
+	SRC_URI="https://downloads.lxqt.org/lxqt/${PV}/${P}.tar.xz"
+	KEYWORDS="~amd64   ~x86"
+fi
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+
+DEPEND="dev-libs/glib:2
+	dev-libs/liboobs
+	>=dev-libs/libqtxdg-1.0.0
+	dev-qt/qtcore:5
+	dev-qt/qtdbus:5
+	dev-qt/qtgui:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtx11extras:5
+	dev-qt/qtxml:5
+	~lxqt-base/liblxqt-${PV}
+	kde-frameworks/kwindowsystem:5
+	x11-libs/libX11
+"
+RDEPEND="${DEPEND}"
diff --git a/lxqt-base/lxqt-common/lxqt-common-0.10.0.ebuild b/lxqt-base/lxqt-common/lxqt-common-0.10.0.ebuild
new file mode 100644
index 00000000000..0a9344610d2
--- /dev/null
+++ b/lxqt-base/lxqt-common/lxqt-common-0.10.0.ebuild
@@ -0,0 +1,30 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+inherit cmake-utils
+
+DESCRIPTION="LXQt common resources"
+HOMEPAGE="http://lxqt.org/"
+
+if [[ ${PV} = *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="git://git.lxde.org/git/lxde/${PN}.git"
+else
+	SRC_URI="https://downloads.lxqt.org/lxqt/${PV}/${P}.tar.xz"
+	KEYWORDS="~amd64   ~x86"
+fi
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+
+DEPEND=">=lxqt-base/liblxqt-0.10.0"
+RDEPEND="${DEPEND}"
+PDEPEND=">=lxqt-base/lxqt-session-0.10.0"
+
+src_install() {
+	cmake-utils_src_install
+	dodir "/etc/X11/Sessions"
+	dosym  "/usr/bin/startlxqt" "/etc/X11/Sessions/lxqt"
+}
diff --git a/lxqt-base/lxqt-config/lxqt-config-0.10.0.ebuild b/lxqt-base/lxqt-config/lxqt-config-0.10.0.ebuild
new file mode 100644
index 00000000000..bb2ad072f14
--- /dev/null
+++ b/lxqt-base/lxqt-config/lxqt-config-0.10.0.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+inherit cmake-utils
+
+DESCRIPTION="LXQt system configuration control center"
+HOMEPAGE="http://lxqt.org/"
+
+if [[ ${PV} = *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="git://git.lxde.org/git/lxde/${PN}.git"
+else
+	SRC_URI="https://downloads.lxqt.org/lxqt/${PV}/${P}.tar.xz"
+	KEYWORDS="~amd64   ~x86"
+fi
+
+LICENSE="GPL-2 LGPL-2.1+"
+SLOT="0"
+
+DEPEND="
+	>=dev-libs/libqtxdg-1.0.0
+	dev-qt/linguist-tools:5
+	dev-qt/qtconcurrent:5
+	dev-qt/qtcore:5
+	dev-qt/qtdbus:5
+	dev-qt/qtgui:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtx11extras:5
+	dev-qt/qtxml:5
+	kde-frameworks/kwindowsystem:5
+	kde-plasma/libkscreen
+	~lxqt-base/liblxqt-${PV}
+	sys-libs/zlib
+	x11-libs/libICE
+	x11-libs/libSM
+	x11-libs/libxcb:=
+	x11-libs/libX11
+	x11-libs/libXcursor
+	x11-libs/libXext
+	x11-libs/libXfixes"
+RDEPEND="${DEPEND}
+	x11-apps/setxkbmap"
+
+src_install(){
+	cmake-utils_src_install
+	doman man/*.1 liblxqt-config-cursor/man/*.1 lxqt-config-appearance/man/*.1
+}
diff --git a/lxqt-base/lxqt-globalkeys/lxqt-globalkeys-0.10.0.ebuild b/lxqt-base/lxqt-globalkeys/lxqt-globalkeys-0.10.0.ebuild
new file mode 100644
index 00000000000..5371c5eb0ca
--- /dev/null
+++ b/lxqt-base/lxqt-globalkeys/lxqt-globalkeys-0.10.0.ebuild
@@ -0,0 +1,38 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+inherit cmake-utils
+
+DESCRIPTION="Daemon and library for global keyboard shortcuts registration"
+HOMEPAGE="http://lxqt.org/"
+
+if [[ ${PV} = *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="git://git.lxde.org/git/lxde/${PN}.git"
+else
+	SRC_URI="https://downloads.lxqt.org/lxqt/${PV}/${P}.tar.xz"
+	KEYWORDS="~amd64   ~x86"
+fi
+
+LICENSE="GPL-2 LGPL-2.1+"
+SLOT="0"
+
+RDEPEND="
+	dev-qt/qtcore:5
+	dev-qt/qtdbus:5
+	dev-qt/qtgui:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtx11extras:5
+	dev-qt/qtxml:5
+	~lxqt-base/liblxqt-${PV}
+	>=dev-libs/libqtxdg-1.0.0
+	x11-libs/libICE
+	x11-libs/libSM
+	x11-libs/libX11
+	x11-libs/libXext
+"
+DEPEND="${RDEPEND}
+	dev-qt/linguist-tools:5
+"
diff --git a/lxqt-base/lxqt-meta/lxqt-meta-0.10.0.ebuild b/lxqt-base/lxqt-meta/lxqt-meta-0.10.0.ebuild
new file mode 100644
index 00000000000..9e9aa5a99f4
--- /dev/null
+++ b/lxqt-base/lxqt-meta/lxqt-meta-0.10.0.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+DESCRIPTION="Meta ebuild for LXQt, the Lightweight Desktop Environment"
+HOMEPAGE="http://lxqt.org/"
+
+LICENSE="metapackage"
+SLOT="0"
+KEYWORDS="~amd64   ~x86"
+IUSE="+about admin +filemanager +icons lightdm lximage minimal +oxygen +policykit
+	powermanagement sddm ssh-askpass sudo"
+REQUIRED_USE="oxygen? ( icons )"
+
+RDEPEND="
+	>=lxde-base/lxmenu-data-0.1.2
+	=lxqt-base/lxqt-common-0.10*
+	~lxqt-base/lxqt-config-${PV}
+	~lxqt-base/lxqt-globalkeys-${PV}
+	~lxqt-base/lxqt-notificationd-${PV}
+	~lxqt-base/lxqt-panel-${PV}
+	~lxqt-base/lxqt-qtplugin-${PV}
+	~lxqt-base/lxqt-runner-${PV}
+	~lxqt-base/lxqt-session-${PV}
+	virtual/ttf-fonts
+	about? ( ~lxqt-base/lxqt-about-${PV} )
+	admin? ( ~lxqt-base/lxqt-admin-${PV} )
+	filemanager? ( ~x11-misc/pcmanfm-qt-${PV} )
+	icons? ( oxygen? ( kde-frameworks/oxygen-icons )
+		!oxygen? ( virtual/freedesktop-icon-theme ) )
+	lightdm? ( x11-misc/lightdm )
+	lximage? ( media-gfx/lximage-qt )
+	!minimal? ( x11-wm/openbox
+		x11-misc/obconf-qt )
+	policykit? ( ~lxqt-base/lxqt-policykit-${PV}
+		|| ( sys-auth/consolekit[policykit(-)]
+			sys-apps/systemd[policykit(-)] ) )
+	powermanagement? ( ~lxqt-base/lxqt-powermanagement-${PV} )
+	sddm? ( >=x11-misc/sddm-0.11.0 )
+	ssh-askpass? ( ~lxqt-base/lxqt-openssh-askpass-${PV} )
+	sudo? ( ~lxqt-base/lxqt-sudo-${PV} )"
+
+# Note: we prefer kde-frameworks/oxygen-icons over other icon sets, as the initial
+# install expects oxygen icons, until the user specifies otherwise (bug 543380)
+
+S="${WORKDIR}"
diff --git a/lxqt-base/lxqt-meta/metadata.xml b/lxqt-base/lxqt-meta/metadata.xml
index 8c70e458d04..14f3ec8d696 100644
--- a/lxqt-base/lxqt-meta/metadata.xml
+++ b/lxqt-base/lxqt-meta/metadata.xml
@@ -3,7 +3,8 @@
 <pkgmetadata>
   <herd>lxqt</herd>
   <use>
-    <flag name="admin">Install <pkg>app-admin/lxqt-admin</pkg></flag>
+    <flag name="about">Install <pkg>lxqt-base/lxqt-about</pkg></flag>
+    <flag name="admin">Install <pkg>lxqt-base/lxqt-admin</pkg></flag>
     <flag name="filemanager">Install <pkg>x11-misc/pcmanfm-qt</pkg>
     file manager</flag>
     <flag name="icons">Install an icon theme</flag>
@@ -13,12 +14,13 @@
     image viewer</flag>
     <flag name="minimal">Do not install <pkg>x11-wm/openbox</pkg>
     window manager</flag>
-    <flag name="oxygen">Prefer <pkg>kde-apps/oxygen-icons</pkg> (default)</flag>
+    <flag name="oxygen">Prefer <pkg>kde-frameworks/oxygen-icons</pkg> (default)</flag>
     <flag name="powermanagement">Install
     <pkg>lxqt-base/lxqt-powermanagement</pkg> package</flag>
     <flag name="sddm">Install <pkg>x11-misc/sddm</pkg>
     display manager</flag>
-    <flag name="ssh-askpass">Install <pkg>net-misc/lxqt-openssh-askpass</pkg>
+    <flag name="ssh-askpass">Install <pkg>lxqt-base/lxqt-openssh-askpass</pkg>
     user password prompt tool</flag>
+    <flag name="sudo">Install <pkg>lxqt-base/lxqt-sudo</pkg></flag>
   </use>
 </pkgmetadata>
diff --git a/lxqt-base/lxqt-notificationd/lxqt-notificationd-0.10.0.ebuild b/lxqt-base/lxqt-notificationd/lxqt-notificationd-0.10.0.ebuild
new file mode 100644
index 00000000000..abee34b80c1
--- /dev/null
+++ b/lxqt-base/lxqt-notificationd/lxqt-notificationd-0.10.0.ebuild
@@ -0,0 +1,36 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+inherit cmake-utils
+
+DESCRIPTION="LXQt notification daemon and library"
+HOMEPAGE="http://lxqt.org/"
+
+if [[ ${PV} = *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="git://git.lxde.org/git/lxde/${PN}.git"
+else
+	SRC_URI="https://downloads.lxqt.org/lxqt/${PV}/${P}.tar.xz"
+	KEYWORDS="~amd64   ~x86"
+fi
+
+LICENSE="GPL-2 LGPL-2.1+"
+SLOT="0"
+
+RDEPEND="
+	>=dev-libs/libqtxdg-1.0.0
+	dev-qt/qtcore:5
+	dev-qt/qtdbus:5
+	dev-qt/qtgui:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtx11extras:5
+	dev-qt/qtxml:5
+	kde-frameworks/kwindowsystem:5
+	~lxqt-base/liblxqt-${PV}
+	=lxqt-base/lxqt-common-0.10*
+"
+DEPEND="${RDEPEND}
+	dev-qt/linguist-tools:5
+"
diff --git a/lxqt-base/lxqt-openssh-askpass/lxqt-openssh-askpass-0.10.0.ebuild b/lxqt-base/lxqt-openssh-askpass/lxqt-openssh-askpass-0.10.0.ebuild
new file mode 100644
index 00000000000..ce2f76c7bf1
--- /dev/null
+++ b/lxqt-base/lxqt-openssh-askpass/lxqt-openssh-askpass-0.10.0.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+inherit cmake-utils
+
+DESCRIPTION="LXQt OpenSSH user password prompt tool"
+HOMEPAGE="http://lxqt.org/"
+
+if [[ ${PV} = *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="git://git.lxde.org/git/lxde/${PN}.git"
+else
+	SRC_URI="https://downloads.lxqt.org/lxqt/${PV}/${P}.tar.xz"
+	KEYWORDS="~amd64   ~x86"
+fi
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+
+RDEPEND="
+	>=dev-libs/libqtxdg-1.0.0
+	dev-qt/qtcore:5
+	dev-qt/qtdbus:5
+	dev-qt/qtgui:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtx11extras:5
+	dev-qt/qtxml:5
+	~lxqt-base/liblxqt-${PV}
+	x11-libs/libX11
+"
+DEPEND="${RDEPEND}
+	dev-qt/linguist-tools:5
+"
+
+src_install(){
+	cmake-utils_src_install
+	doman man/*.1
+
+	echo "SSH_ASKPASS='${EPREFIX}/usr/bin/lxqt-openssh-askpass'" >> "${T}/99${PN}" \
+		|| die
+	doenvd "${T}/99${PN}"
+}
diff --git a/lxqt-base/lxqt-panel/lxqt-panel-0.10.0.ebuild b/lxqt-base/lxqt-panel/lxqt-panel-0.10.0.ebuild
new file mode 100644
index 00000000000..5072ce04d97
--- /dev/null
+++ b/lxqt-base/lxqt-panel/lxqt-panel-0.10.0.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+inherit cmake-utils
+
+DESCRIPTION="LXQt desktop panel and plugins"
+HOMEPAGE="http://lxqt.org/"
+
+if [[ ${PV} = *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="git://git.lxde.org/git/lxde/${PN}.git"
+else
+	SRC_URI="https://downloads.lxqt.org/lxqt/${PV}/${P}.tar.xz"
+	KEYWORDS="~amd64   ~x86"
+fi
+
+LICENSE="GPL-2 LGPL-2.1+"
+SLOT="0"
+IUSE="+alsa +clock colorpicker cpuload +desktopswitch dom +kbindicator +mainmenu
+	+mount networkmonitor pulseaudio +quicklaunch screensaver sensors
+	+showdesktop statusnotifier sysstat +taskbar +tray +volume worldclock"
+REQUIRED_USE="volume? ( || ( alsa pulseaudio ) )"
+
+DEPEND="
+	dev-libs/glib:2
+	>=dev-libs/libqtxdg-1.0.0
+	dev-qt/linguist-tools:5
+	dev-qt/qtcore:5
+	dev-qt/qtdbus:5
+	dev-qt/qtgui:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtx11extras:5
+	dev-qt/qtxml:5
+	kde-frameworks/kguiaddons:5
+	kde-frameworks/kwindowsystem:5[X]
+	>=lxde-base/menu-cache-0.3.3
+	~lxqt-base/liblxqt-${PV}
+	~lxqt-base/lxqt-globalkeys-${PV}
+	x11-libs/libX11
+	cpuload? ( sys-libs/libstatgrab )
+	kbindicator? ( x11-libs/libxkbcommon )
+	mount? ( kde-frameworks/solid:5 )
+	networkmonitor? ( sys-libs/libstatgrab )
+	sensors? ( sys-apps/lm_sensors )
+	statusnotifier? ( dev-libs/libdbusmenu-qt[qt5] )
+	sysstat? ( =lxqt-base/libsysstat-0.3* )
+	tray? ( x11-libs/libXcomposite
+		x11-libs/libXdamage
+		x11-libs/libXrender )
+	volume? ( alsa? ( media-libs/alsa-lib )
+		pulseaudio? ( media-sound/pulseaudio ) )"
+RDEPEND="${DEPEND}
+	dev-qt/qtsvg:5
+	>=lxde-base/lxmenu-data-0.1.2"
+
+src_configure() {
+	local mycmakeargs i y
+	for i in clock colorpicker cpuload desktopswitch dom kbindicator mainmenu mount \
+		networkmonitor quicklaunch screensaver sensors showdesktop statusnotifier \
+		sysstat taskbar tray volume worldclock; do
+		#Switch to ^^ when we switch to EAPI=6.
+		#y=${i^^}
+		y=$(tr '[:lower:]' '[:upper:]' <<< "${i}")
+		mycmakeargs+=( $(cmake-utils_use ${i} ${y}_PLUGIN) )
+	done
+
+	if use volume; then
+		mycmakeargs+=( $(cmake-utils_use alsa VOLUME_USE_ALSA)
+			$(cmake-utils_use pulseaudio VOLUME_USE_PULSEAUDIO) )
+	fi
+
+	cmake-utils_src_configure
+}
+
+src_install(){
+	cmake-utils_src_install
+	doman panel/man/*.1
+}
diff --git a/lxqt-base/lxqt-panel/metadata.xml b/lxqt-base/lxqt-panel/metadata.xml
index 7948c162e91..0b16db70280 100644
--- a/lxqt-base/lxqt-panel/metadata.xml
+++ b/lxqt-base/lxqt-panel/metadata.xml
@@ -20,6 +20,7 @@
     <flag name="screensaver">Build screensaver plugin</flag>
     <flag name="sensors">Build sensors plugin</flag>
     <flag name="showdesktop">Build showdesktop plugin</flag>
+    <flag name="statusnotifier">Build statusnotifier plugin</flag>
     <flag name="sysstat">Build sysstat plugin</flag>
     <flag name="taskbar">Build taskbar plugin</flag>
     <flag name="teatime">Build teatime plugin</flag>
diff --git a/lxqt-base/lxqt-policykit/lxqt-policykit-0.10.0.ebuild b/lxqt-base/lxqt-policykit/lxqt-policykit-0.10.0.ebuild
new file mode 100644
index 00000000000..3ef7e6eca64
--- /dev/null
+++ b/lxqt-base/lxqt-policykit/lxqt-policykit-0.10.0.ebuild
@@ -0,0 +1,40 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+inherit cmake-utils
+
+DESCRIPTION="LXQt PolKit authentication agent"
+HOMEPAGE="http://lxqt.org/"
+
+if [[ ${PV} = *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="git://git.lxde.org/git/lxde/${PN}.git"
+else
+	SRC_URI="https://downloads.lxqt.org/lxqt/${PV}/${P}.tar.xz"
+	KEYWORDS="~amd64   ~x86"
+fi
+
+LICENSE="GPL-2 LGPL-2.1+"
+SLOT="0"
+
+RDEPEND="
+	dev-libs/glib:2
+	dev-qt/qtcore:5
+	dev-qt/qtdbus:5
+	dev-qt/qtgui:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtx11extras:5
+	dev-qt/qtxml:5
+	~lxqt-base/liblxqt-${PV}
+	>=dev-libs/libqtxdg-1.0.0
+	sys-auth/polkit-qt[qt5(-)]"
+DEPEND="${RDEPEND}
+	dev-qt/linguist-tools:5
+	virtual/pkgconfig"
+
+src_install(){
+	cmake-utils_src_install
+	doman man/*.1
+}
diff --git a/lxqt-base/lxqt-powermanagement/lxqt-powermanagement-0.10.0.ebuild b/lxqt-base/lxqt-powermanagement/lxqt-powermanagement-0.10.0.ebuild
new file mode 100644
index 00000000000..d3f01e6320b
--- /dev/null
+++ b/lxqt-base/lxqt-powermanagement/lxqt-powermanagement-0.10.0.ebuild
@@ -0,0 +1,38 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+inherit cmake-utils
+
+DESCRIPTION="LXQt daemon for power management and auto-suspend"
+HOMEPAGE="http://lxqt.org/"
+
+if [[ ${PV} = *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="git://git.lxde.org/git/lxde/${PN}.git"
+else
+	SRC_URI="https://downloads.lxqt.org/lxqt/${PV}/${P}.tar.xz"
+	KEYWORDS="~amd64   ~x86"
+fi
+
+LICENSE="GPL-2 LGPL-2.1+"
+SLOT="0"
+
+CDEPEND="
+	dev-qt/qtcore:5
+	dev-qt/qtdbus:5
+	dev-qt/qtgui:5
+	dev-qt/qtsvg:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtx11extras:5
+	dev-qt/qtxml:5
+	~lxqt-base/liblxqt-${PV}
+	>=dev-libs/libqtxdg-1.0.0
+	x11-libs/libX11
+	x11-libs/libxcb:="
+DEPEND="${CDEPEND}
+	dev-qt/linguist-tools:5
+	virtual/pkgconfig"
+RDEPEND="${CDEPEND}
+	|| ( sys-power/upower sys-power/upower-pm-utils )"
diff --git a/lxqt-base/lxqt-qtplugin/lxqt-qtplugin-0.10.0.ebuild b/lxqt-base/lxqt-qtplugin/lxqt-qtplugin-0.10.0.ebuild
new file mode 100644
index 00000000000..30249409157
--- /dev/null
+++ b/lxqt-base/lxqt-qtplugin/lxqt-qtplugin-0.10.0.ebuild
@@ -0,0 +1,30 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+inherit cmake-utils
+
+DESCRIPTION="LXQt system integration plugin for Qt"
+HOMEPAGE="http://lxqt.org/"
+
+if [[ ${PV} = *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="git://git.lxde.org/git/lxde/${PN}.git"
+else
+	SRC_URI="https://downloads.lxqt.org/lxqt/${PV}/${P}.tar.xz"
+	KEYWORDS="~amd64   ~x86"
+fi
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+
+RDEPEND="
+	dev-libs/libdbusmenu-qt[qt5]
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtwidgets:5
+	~lxqt-base/liblxqt-${PV}
+	x11-libs/libX11"
+DEPEND="${RDEPEND}
+	dev-qt/linguist-tools:5"
diff --git a/lxqt-base/lxqt-runner/lxqt-runner-0.10.0.ebuild b/lxqt-base/lxqt-runner/lxqt-runner-0.10.0.ebuild
new file mode 100644
index 00000000000..510c91f6648
--- /dev/null
+++ b/lxqt-base/lxqt-runner/lxqt-runner-0.10.0.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+inherit cmake-utils
+
+DESCRIPTION="LXQt quick launcher"
+HOMEPAGE="http://lxqt.org/"
+
+if [[ ${PV} = *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="git://git.lxde.org/git/lxde/${PN}.git"
+else
+	SRC_URI="https://downloads.lxqt.org/lxqt/${PV}/${P}.tar.xz"
+	KEYWORDS="~amd64   ~x86"
+fi
+
+LICENSE="GPL-2 LGPL-2.1+"
+SLOT="0"
+
+RDEPEND="dev-libs/glib:2
+	>=dev-libs/libqtxdg-1.0.0
+	dev-qt/qtcore:5
+	dev-qt/qtdbus:5
+	dev-qt/qtscript:5
+	dev-qt/qtgui:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtx11extras:5
+	dev-qt/qtxml:5
+	kde-frameworks/kwindowsystem:5
+	>=lxde-base/menu-cache-0.5.1
+	~lxqt-base/liblxqt-${PV}
+	~lxqt-base/lxqt-globalkeys-${PV}"
+DEPEND="${RDEPEND}
+	dev-qt/linguist-tools:5
+	virtual/pkgconfig"
+
+src_install(){
+	cmake-utils_src_install
+	doman man/*.1
+}
diff --git a/lxqt-base/lxqt-session/lxqt-session-0.10.0.ebuild b/lxqt-base/lxqt-session/lxqt-session-0.10.0.ebuild
new file mode 100644
index 00000000000..107e5a40cfa
--- /dev/null
+++ b/lxqt-base/lxqt-session/lxqt-session-0.10.0.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+inherit cmake-utils
+
+DESCRIPTION="LXQT session manager"
+HOMEPAGE="http://lxqt.org/"
+
+if [[ ${PV} = *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="git://git.lxde.org/git/lxde/${PN}.git"
+else
+	SRC_URI="https://downloads.lxqt.org/lxqt/${PV}/${P}.tar.xz"
+	KEYWORDS="~amd64   ~x86"
+fi
+
+LICENSE="GPL-2 LGPL-2.1+"
+SLOT="0"
+
+CDEPEND="
+	>=dev-libs/libqtxdg-1.0.0
+	dev-qt/qtcore:5
+	dev-qt/qtdbus:5
+	dev-qt/qtgui:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtx11extras:5
+	dev-qt/qtxml:5
+	kde-frameworks/kwindowsystem:5[X]
+	~lxqt-base/liblxqt-${PV}
+	x11-libs/libX11"
+DEPEND="${CDEPEND}
+	dev-qt/linguist-tools:5
+	dev-util/intltool
+	sys-devel/gettext
+	virtual/pkgconfig"
+RDEPEND="${CDEPEND}
+	=lxqt-base/lxqt-common-0.10*"
+
+src_install(){
+	cmake-utils_src_install
+	doman lxqt-config-session/man/*.1 lxqt-session/man/*.1
+}
diff --git a/lxqt-base/lxqt-sudo/lxqt-sudo-0.10.0.ebuild b/lxqt-base/lxqt-sudo/lxqt-sudo-0.10.0.ebuild
new file mode 100644
index 00000000000..368c0c09761
--- /dev/null
+++ b/lxqt-base/lxqt-sudo/lxqt-sudo-0.10.0.ebuild
@@ -0,0 +1,30 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+inherit cmake-utils
+
+DESCRIPTION="LXQt GUI frontend for sudo"
+HOMEPAGE="http://lxqt.org/"
+
+if [[ ${PV} = *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="git://git.lxde.org/git/lxde/${PN}.git"
+else
+	SRC_URI="https://downloads.lxqt.org/lxqt/${PV}/${P}.tar.xz"
+	KEYWORDS="~amd64   ~x86"
+fi
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+
+DEPEND="app-admin/sudo
+	>=dev-libs/libqtxdg-1.0.0
+	dev-qt/qtcore:5
+	dev-qt/qtdbus:5
+	dev-qt/qtgui:5
+	dev-qt/qtwidgets:5
+	~lxqt-base/liblxqt-${PV}
+	"
+RDEPEND="${DEPEND}"
diff --git a/x11-misc/pcmanfm-qt/pcmanfm-qt-0.10.0.ebuild b/x11-misc/pcmanfm-qt/pcmanfm-qt-0.10.0.ebuild
new file mode 100644
index 00000000000..16f804bbe32
--- /dev/null
+++ b/x11-misc/pcmanfm-qt/pcmanfm-qt-0.10.0.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+inherit cmake-utils multilib readme.gentoo
+
+if [[ "${PV}" == "9999" ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="git://git.lxde.org/git/lxde/${PN}"
+else
+	SRC_URI="https://downloads.lxqt.org/lxqt/${PV}/${P}.tar.xz"
+	KEYWORDS="~amd64   ~x86"
+fi
+
+DESCRIPTION="Fast lightweight tabbed filemanager (Qt port)"
+HOMEPAGE="http://pcmanfm.sourceforge.net/"
+
+LICENSE="GPL-2 LGPL-2.1+"
+SLOT="0"
+
+CDEPEND=">=dev-libs/glib-2.18:2
+	dev-qt/qtcore:5
+	dev-qt/qtdbus:5
+	dev-qt/qtgui:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtx11extras:5
+	>=lxde-base/menu-cache-0.4.1
+	>=x11-libs/libfm-1.2.0
+	x11-libs/libxcb:=
+"
+RDEPEND="${CDEPEND}
+	x11-misc/xdg-utils
+	virtual/eject
+	virtual/freedesktop-icon-theme"
+DEPEND="${CDEPEND}
+	dev-qt/linguist-tools:5
+	>=dev-util/intltool-0.40
+	sys-devel/gettext
+	virtual/pkgconfig"
+
+src_prepare() {
+	# fix multilib
+	sed -i -e "/LIBRARY\ DESTINATION/s:lib:$(get_libdir):" \
+		libfm-qt/CMakeLists.txt || die
+	cmake-utils_src_prepare
+}
+
+src_install() {
+	cmake-utils_src_install
+	DOC_CONTENTS="Be sure to set an icon theme in Edit > Preferences > User Interface"
+	readme.gentoo_src_install
+}