app-admin/yadm: version bump.

Closes: https://bugs.gentoo.org/642660
Package-Manager: Portage-2.3.13, Repoman-2.3.3

1 files changed, 53 insertions, 0 deletions

diff --git a/app-admin/yadm/yadm-1.12.0.ebuild b/app-admin/yadm/yadm-1.12.0.ebuild
new file mode 100644
index 00000000000..e6b2381a71f
--- /dev/null
+++ b/app-admin/yadm/yadm-1.12.0.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit bash-completion-r1
+
+DESCRIPTION="A dotfile manager for the config files in your home folder"
+HOMEPAGE="https://github.com/TheLocehiliosan/yadm/"
+SRC_URI="https://github.com/TheLocehiliosan/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="zsh-completion test"
+
+DEPEND="
+	test? (
+		dev-tcltk/expect
+		dev-util/bats
+		dev-vcs/git
+	)"
+
+RDEPEND="
+	dev-vcs/git
+	app-crypt/gnupg
+	zsh-completion? ( app-shells/gentoo-zsh-completions )"
+
+src_compile() {
+	emake "${PN}.md"
+}
+
+src_test() {
+	# 109_accept_encryption tests are interactive, thus fail. Skip them
+	# 113_accept_jinja_alt.bats are depepending on the optional envtpl
+	while IFS="" read -d $'\0' -r f ; do
+		bats "${f}" || die "test ${f} failed"
+	done < <(find test -name '*.bats' -and -not -name '109_accept_encryption.bats' -and -not -name '113_accept_jinja_alt.bats' -print0)
+}
+
+src_install() {
+	einstalldocs
+
+	dobin "${PN}"
+	doman "${PN}.1"
+
+	dobashcomp completion/yadm.bash_completion
+
+	if use zsh-completion; then
+		insinto /usr/share/zsh/site-functions
+		newins completion/yadm.zsh_completion _${PN}
+	fi
+}