app-shells/rc: EAPI 6 bump.

Package-Manager: portage-2.3.3

1 files changed, 45 insertions, 0 deletions

diff --git a/app-shells/rc/rc-1.7.4-r1.ebuild b/app-shells/rc/rc-1.7.4-r1.ebuild
new file mode 100644
index 00000000000..22cf47f1d49
--- /dev/null
+++ b/app-shells/rc/rc-1.7.4-r1.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+DESCRIPTION="A reimplementation of the Plan 9 shell"
+HOMEPAGE="http://static.tobold.org/"
+SRC_URI="http://static.tobold.org/${PN}/${P}.tar.gz"
+
+LICENSE="rc"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="libedit readline"
+
+RDEPEND="readline? ( sys-libs/readline:0 )
+	libedit? ( dev-libs/libedit )"
+DEPEND="${RDEPEND}"
+
+DOCS=( AUTHORS ChangeLog NEWS README )
+
+src_configure() {
+	local myconf="--with-history"
+	use readline && myconf="--with-edit=readline"
+	use libedit && myconf="--with-edit=edit"
+
+	econf \
+		--disable-dependency-tracking \
+		"${myconf}"
+}
+
+src_install() {
+	into /
+	newbin "${PN}" "${PN}sh"
+	newman "${PN}.1" "${PN}sh.1"
+	einstalldocs
+}
+
+pkg_postinst() {
+	if ! grep -q '^/bin/rcsh$' "${EROOT}"/etc/shells ; then
+		ebegin "Updating /etc/shells"
+		echo "/bin/rcsh" >> "${EROOT}"/etc/shells
+		eend $?
+	fi
+}