proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 53 insertions, 0 deletions

diff --git a/app-text/pdf2djvu/pdf2djvu-0.7.21.ebuild b/app-text/pdf2djvu/pdf2djvu-0.7.21.ebuild
new file mode 100644
index 00000000000..653e9bbc712
--- /dev/null
+++ b/app-text/pdf2djvu/pdf2djvu-0.7.21.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+PYTHON_COMPAT=( python2_7 )
+
+inherit python-single-r1 toolchain-funcs
+
+DESCRIPTION="A tool to create DjVu files from PDF files"
+HOMEPAGE="http://jwilk.net/software/pdf2djvu"
+SRC_URI="https://bitbucket.org/jwilk/${PN}/downloads/${P}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+graphicsmagick nls openmp test"
+
+RDEPEND="
+	>=app-text/djvu-3.5.21:=
+	>=app-text/poppler-0.16.7:=
+	dev-libs/libxml2:=
+	dev-libs/libxslt:=
+	graphicsmagick? ( media-gfx/graphicsmagick:= )
+"
+DEPEND="${RDEPEND}
+	dev-cpp/pstreams
+	virtual/pkgconfig
+	nls? ( sys-devel/gettext )
+	test? ( dev-python/nose[${PYTHON_USEDEP}] )
+"
+
+REQUIRED_USE="test? ( graphicsmagick ${PYTHON_REQUIRED_USE} )"
+
+pkg_setup() {
+	use test && python-single-r1_pkg_setup
+}
+
+src_configure() {
+	local openmp=--disable-openmp
+	use openmp && tc-has-openmp && openmp=--enable-openmp
+
+	econf \
+		${openmp} \
+		$(use_enable nls) \
+		$(use_with graphicsmagick)
+}
+
+src_install() {
+	default
+	dodoc doc/{changelog,{cjk,credits,djvudigital}.txt}
+}