dev-java/annogen: Do away with hacks and make use of java-pkg-simple. Keywords for ppc+ppc64+x86.

Package-Manager: portage-2.2.20.1
Signed-off-by: Patrice Clement <monsieurp@gentoo.org>

3 files changed, 58 insertions, 143 deletions

diff --git a/dev-java/annogen/annogen-0.1.0-r1.ebuild b/dev-java/annogen/annogen-0.1.0-r1.ebuild
deleted file mode 100644
index 4c09b7bb1f7..00000000000
--- a/dev-java/annogen/annogen-0.1.0-r1.ebuild
+++ /dev/null
@@ -1,72 +0,0 @@
-# Copyright 1999-2015 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Id$
-
-EAPI="5"
-
-JAVA_PKG_IUSE="doc source examples"
-
-inherit eutils java-pkg-2 java-ant-2
-
-DESCRIPTION="A tool which helps you work with JSR175 annotations"
-HOMEPAGE="https://github.com/codehaus/annogen"
-SRC_URI="http://dist.codehaus.org/${PN}/distributions/${P}.zip"
-
-LICENSE="BSD"
-SLOT="0"
-KEYWORDS="~amd64"
-
-CDEPEND="java-virtuals/jdk-with-com-sun:0
-	dev-java/ant-core:0
-	dev-java/qdox:1.6"
-
-RDEPEND=">=virtual/jdk-1.6
-		${CDEPEND}"
-
-DEPEND=">=virtual/jre-1.6
-		app-arch/unzip
-		${CDEPEND}"
-
-S="${WORKDIR}"
-
-# com.sun.mirror.declaration was removed from JDK 7 onwards.
-# These two files are just interfaces anyway.
-JAVA_RM_FILES=(
-	org/codehaus/annogen/view/MirrorAnnoViewer.java
-	org/codehaus/annogen/override/MirrorElementIdPool.java
-)
-
-src_unpack() {
-	default
-	unzip -o -q "${S}/${PN}-src-${PV}.zip" || die
-}
-
-java_prepare() {
-	find -name '*.jar' -exec rm -v {} + || die
-	mkdir "${S}"/classes || die
-}
-
-# Well. I don't like this way of doing things but it works.
-# I've tried to rewrite this ebuild using the java-ant-2 eclass.
-# It was an unfruitful try.
-src_compile() {
-	find org -name "*.java" > "${T}/src.list" || die
-
-	ejavac -d "${S}"/classes \
-		-classpath $(java-pkg_getjars qdox-1.6,ant-core):$(java-config --tools) \
-		"@${T}/src.list"
-
-	cd "${S}"/classes || die
-	jar -cf "${S}/${PN}.jar" * || die "failed to create jar"
-}
-
-src_install() {
-	java-pkg_dojar ${PN}.jar
-
-	# For if this is ever needed:
-	# java-pkg_register-ant-task
-
-	use doc && java-pkg_dojavadoc docs
-	use source && java-pkg_dosrc org
-	use examples && java-pkg_doexamples "examples"
-}
diff --git a/dev-java/annogen/annogen-0.1.0-r2.ebuild b/dev-java/annogen/annogen-0.1.0-r2.ebuild
new file mode 100644
index 00000000000..6bb96418f74
--- /dev/null
+++ b/dev-java/annogen/annogen-0.1.0-r2.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+JAVA_PKG_IUSE="doc source"
+
+inherit java-pkg-2 java-pkg-simple
+
+DESCRIPTION="A tool which helps you work with JSR175 annotations"
+HOMEPAGE="https://github.com/codehaus/annogen"
+SRC_URI="http://dist.codehaus.org/${PN}/distributions/${P}.zip"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+
+CDEPEND="
+	dev-java/qdox:1.6
+	dev-java/ant-core:0
+	java-virtuals/jdk-with-com-sun:0"
+
+RDEPEND="
+	${CDEPEND}
+	>=virtual/jdk-1.6"
+
+DEPEND="
+	${CDEPEND}
+	app-arch/unzip
+	>=virtual/jre-1.6"
+
+# com.sun.mirror.declaration was removed from JDK 7 onwards.
+# These two files are just interfaces anyway.
+JAVA_RM_FILES=(
+	org/codehaus/annogen/view/MirrorAnnoViewer.java
+	org/codehaus/annogen/override/MirrorElementIdPool.java
+)
+
+JAVA_GENTOO_CLASSPATH="
+	ant-core
+	qdox-1.6
+"
+
+src_unpack() {
+	default
+	unzip -o -q "${S}/${PN}-src-${PV}.zip" || die
+}
+
+java_prepare() {
+	java-pkg_clean
+	rm -rf examples || die
+}
+
+src_compile() {
+	# Needed for com.sun.* imports
+	JAVA_GENTOO_CLASSPATH_EXTRA="$(java-config -t)" \
+		java-pkg-simple_src_compile
+}
diff --git a/dev-java/annogen/annogen-0.1.0.ebuild b/dev-java/annogen/annogen-0.1.0.ebuild
deleted file mode 100644
index d03f59edc70..00000000000
--- a/dev-java/annogen/annogen-0.1.0.ebuild
+++ /dev/null
@@ -1,71 +0,0 @@
-# Copyright 1999-2015 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Id$
-
-EAPI="5"
-
-JAVA_PKG_IUSE="doc source examples"
-
-inherit eutils java-pkg-2 java-ant-2
-
-DESCRIPTION="A tool which helps you work with JSR175 annotations"
-HOMEPAGE="http://annogen.codehaus.org/"
-SRC_URI="http://dist.codehaus.org/${PN}/distributions/${P}.zip"
-
-LICENSE="BSD"
-SLOT="0"
-KEYWORDS="amd64"
-
-CDEPEND="java-virtuals/stax-api:0
-	java-virtuals/jdk-with-com-sun:0
-	dev-java/ant-core:0
-	dev-java/qdox:1.6"
-
-RDEPEND=">=virtual/jdk-1.6
-		${CDEPEND}"
-
-DEPEND=">=virtual/jre-1.6
-		app-arch/unzip
-		${CDEPEND}"
-
-S="${WORKDIR}"
-
-# com.sun.mirror.declaration was removed from JDK 7 onwards.
-# These two files are just interfaces anyway.
-JAVA_RM_FILES=(
-	org/codehaus/annogen/view/MirrorAnnoViewer.java
-	org/codehaus/annogen/override/MirrorElementIdPool.java
-)
-
-src_unpack() {
-	default
-	unzip -o -q "${S}/${PN}-src-${PV}.zip" || die
-}
-
-java_prepare() {
-	find -name '*.jar' -exec rm -v {} + || die
-
-	mkdir "${S}"/classes || die
-}
-
-src_compile() {
-	find org -name "*.java" > "${T}/src.list" || die
-
-	ejavac -d "${S}"/classes \
-		-classpath $(java-pkg_getjars stax-api,qdox-1.6,ant-core):$(java-config --tools) \
-		"@${T}/src.list"
-
-	cd "${S}"/classes || die
-	jar -cf "${S}/${PN}.jar" * || die "failed to create jar"
-}
-
-src_install() {
-	java-pkg_dojar ${PN}.jar
-
-	# For if this is ever needed:
-	# java-pkg_register-ant-task
-
-	use doc && java-pkg_dojavadoc docs
-	use source && java-pkg_dosrc org
-	use examples && java-pkg_doexamples "examples"
-}