dev-python/couchdb-python: version bump to 1.0.1

Package-Manager: portage-2.2.26

1 files changed, 44 insertions, 0 deletions

diff --git a/dev-python/couchdb-python/couchdb-python-1.0.1.ebuild b/dev-python/couchdb-python/couchdb-python-1.0.1.ebuild
new file mode 100644
index 00000000000..198c01c25cf
--- /dev/null
+++ b/dev-python/couchdb-python/couchdb-python-1.0.1.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+PYTHON_COMPAT=( python{2_7,3_3,3_4} pypy )
+
+inherit distutils-r1
+
+MY_PN="CouchDB"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="Python library for working with CouchDB"
+HOMEPAGE="https://github.com/djc/couchdb-python https://pypi.python.org/pypi/CouchDB"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc"
+
+DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )"
+
+S=${WORKDIR}/${MY_P}
+
+# Tests require connectivity to a couchdb server.
+# Re-enable when the ebuild is capable of starting a local couchdb
+# instance.
+RESTRICT=test
+
+python_compile_all() {
+	use doc && esetup.py build_sphinx
+}
+
+python_test() {
+	esetup.py test
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( doc/build/html/. )
+	distutils-r1_python_install_all
+}