dev-python/datashape: Bump

Package-Manager: portage-2.3.0

1 files changed, 46 insertions, 0 deletions

diff --git a/dev-python/datashape/datashape-0.5.3.ebuild b/dev-python/datashape/datashape-0.5.3.ebuild
new file mode 100644
index 00000000000..602a6f46c05
--- /dev/null
+++ b/dev-python/datashape/datashape-0.5.3.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+PYTHON_COMPAT=( python{2_7,3_3,3_4,3_5} )
+
+inherit distutils-r1
+
+DESCRIPTION="Language defining a data description protocol"
+HOMEPAGE="https://github.com/ContinuumIO/datashape"
+SRC_URI="https://github.com/ContinuumIO/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc test"
+
+RDEPEND=">=dev-python/numpy-1.7[${PYTHON_USEDEP}]
+		>=dev-python/multipledispatch-0.4.7[${PYTHON_USEDEP}]
+		dev-python/python-dateutil[${PYTHON_USEDEP}]"
+DEPEND="doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	test? ( ${RDEPEND}
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/pytest[${PYTHON_USEDEP}] )"
+
+python_prepare_all() {
+	# Prevent un-needed d'loading
+	sed -e "s/'sphinx.ext.intersphinx', //" -i docs/source/conf.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_test() {
+	py.test || die "Tests failed under ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/build/html/. )
+	distutils-r1_python_install_all
+}