dev-python/inflection: new package, dependency of flask-bootstrap, vn. 0.3.1

Package-Manager: portage-2.2.28
Closes: https://github.com/gentoo/gentoo/pull/1353

Signed-off-by: Ian Delaney <idella4@gentoo.org>

1 files changed, 42 insertions, 0 deletions

diff --git a/dev-python/inflection/inflection-0.3.1.ebuild b/dev-python/inflection/inflection-0.3.1.ebuild
new file mode 100644
index 00000000000..fac3087875e
--- /dev/null
+++ b/dev-python/inflection/inflection-0.3.1.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+PYTHON_COMPAT=( python{2_7,3_4,3_5} )
+
+inherit distutils-r1
+
+DESCRIPTION="A port of Ruby on Rails inflector to Python"
+HOMEPAGE="https://github.com/jpvanhal/inflection"
+# PyPI tarballs don't include doc
+# https://github.com/jpvanhal/inflection/pull/12
+SRC_URI="https://github.com/jpvanhal/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc test"
+
+RDEPEND=""
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		dev-python/pytest-runner[${PYTHON_USEDEP}]
+		dev-python/pytest[${PYTHON_USEDEP}]
+	)
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+"
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_test() {
+	py.test || die "Tests failed with ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/_build/html/. )
+	distutils-r1_python_install_all
+}