dev-python/python-sqlparse: 0.2.3 bup

Package-Manager: Portage-2.3.6, Repoman-2.3.3

1 files changed, 56 insertions, 0 deletions

diff --git a/dev-python/python-sqlparse/python-sqlparse-0.2.3.ebuild b/dev-python/python-sqlparse/python-sqlparse-0.2.3.ebuild
new file mode 100644
index 00000000000..f2fb7d85117
--- /dev/null
+++ b/dev-python/python-sqlparse/python-sqlparse-0.2.3.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 python3_{4,5,6} pypy )
+
+inherit distutils-r1
+
+MY_PN="${PN##python-}"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="A non-validating SQL parser module for Python"
+HOMEPAGE="https://code.google.com/p/python-sqlparse/ https://github.com/andialbrecht/sqlparse"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
+LICENSE="BSD-2"
+IUSE="doc test"
+
+REQUIRED_USE="doc? ( || ( $(python_gen_useflags 'python2*') ) )"
+
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	test? (
+		dev-python/pytest[${PYTHON_USEDEP}]
+		dev-python/pytest-cov[${PYTHON_USEDEP}]
+		)"
+# Required for running tests
+DISTUTILS_IN_SOURCE_BUILD=1
+
+S="${WORKDIR}"/${P#python-}
+
+pkg_setup() {
+	use doc && DISTUTILS_ALL_SUBPHASE_IMPLS=( 'python2*' )
+}
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_test() {
+	if python_is_python3; then
+		2to3 -w --no-diffs -n tests/ sqlparse/
+		py.test ./tests || die "testsuite failed ${EPYTHON}"
+	else
+		py.test tests || die "testsuite failed under ${EPYTHON}"
+	fi
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/build/html/. )
+	distutils-r1_python_install_all
+}