dev-python/pyzmq: Version Bump

Package-Manager: portage-2.2.23
Signed-off-by: Justin Lecher <jlec@gentoo.org>

1 files changed, 62 insertions, 0 deletions

diff --git a/dev-python/pyzmq/pyzmq-15.0.0.ebuild b/dev-python/pyzmq/pyzmq-15.0.0.ebuild
new file mode 100644
index 00000000000..8b75b12d313
--- /dev/null
+++ b/dev-python/pyzmq/pyzmq-15.0.0.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+PYTHON_COMPAT=( python2_7 python3_{3,4,5} )
+
+inherit distutils-r1 toolchain-funcs
+
+DESCRIPTION="Lightweight and super-fast messaging library built on top of the ZeroMQ library"
+HOMEPAGE="http://www.zeromq.org/bindings:python https://pypi.python.org/pypi/pyzmq"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="LGPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~mips ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos"
+IUSE="doc examples test"
+
+PY2_USEDEP=$(python_gen_usedep python2_7)
+RDEPEND="
+	>=net-libs/zeromq-4.1.2:=
+	dev-python/py[${PYTHON_USEDEP}]
+	dev-python/cffi:=[${PYTHON_USEDEP}]
+	dev-python/gevent[${PY2_USEDEP}]"
+DEPEND="${RDEPEND}
+	test? ( dev-python/nose[${PYTHON_USEDEP}] )
+	doc? (
+		>=dev-python/sphinx-1.3[${PYTHON_USEDEP}]
+		dev-python/numpydoc[${PYTHON_USEDEP}]
+	)"
+
+python_prepare_all() {
+	# Prevent un-needed download during build
+	sed -e "/'sphinx.ext.intersphinx',/d" -i docs/source/conf.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_configure_all() {
+	tc-export CC
+}
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_compile() {
+	python_is_python3 || local -x CFLAGS="${CFLAGS} -fno-strict-aliasing"
+	distutils-r1_python_compile
+}
+
+python_test() {
+	# suite reports error in absence of gevent under py3 but is designed to continue
+	# rather than exit making py3 apt for the test phase
+	nosetests -svw "${BUILD_DIR}/lib/" || die
+}
+
+python_install_all() {
+	use examples && local EXAMPLES=( examples/. )
+	use doc && local HTML_DOCS=( docs/build/html/. )
+	distutils-r1_python_install_all
+}