dev-python/reproject: initial import

Package-Manager: portage-2.2.27

1 files changed, 43 insertions, 0 deletions

diff --git a/dev-python/reproject/reproject-0.2.ebuild b/dev-python/reproject/reproject-0.2.ebuild
new file mode 100644
index 00000000000..aac59ac285a
--- /dev/null
+++ b/dev-python/reproject/reproject-0.2.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+PYTHON_COMPAT=( python{2_7,3_4,3_5} )
+
+inherit distutils-r1
+
+DESCRIPTION="Reproject astronomical images with Python"
+HOMEPAGE="http://reproject.readthedocs.org"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc test"
+
+RDEPEND="
+	dev-python/astropy[${PYTHON_USEDEP}]
+	sci-libs/scipy[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	test? ( dev-python/pytest[${PYTHON_USEDEP}] )"
+
+python_prepare_all() {
+	sed -i -e '/auto_use/s/True/False/' setup.cfg || die
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	use doc && esetup.py build_sphinx -w
+}
+
+python_test() {
+	esetup.py test
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/_build/html/ )
+	distutils-r1_python_install_all
+}