dev-python/vdirsyncer: add req python use sqlite

Suggested-by: Christopher Head <chead@chead.ca>
Closes: https://bugs.gentoo.org/630060

Package-Manager: Portage-2.3.6, Repoman-2.3.1

1 files changed, 47 insertions, 0 deletions

diff --git a/dev-python/vdirsyncer/vdirsyncer-0.16.0-r1.ebuild b/dev-python/vdirsyncer/vdirsyncer-0.16.0-r1.ebuild
new file mode 100644
index 00000000000..a20a3aec23a
--- /dev/null
+++ b/dev-python/vdirsyncer/vdirsyncer-0.16.0-r1.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+
+PYTHON_COMPAT=( python3_{4,5,6} )
+PYTHON_REQ_USE="sqlite"
+
+inherit distutils-r1
+
+DESCRIPTION="Synchronize calendars and contacts"
+HOMEPAGE="https://github.com/pimutils/vdirsyncer"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+KEYWORDS="~amd64 ~x86"
+SLOT="0"
+IUSE="test"
+
+RDEPEND="dev-python/click[${PYTHON_USEDEP}]
+	>=dev-python/click-log-0.1.3[${PYTHON_USEDEP}]
+	>=dev-python/click-threading-0.2[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.4.1[${PYTHON_USEDEP}]
+	!=dev-python/requests-2.9.0[${PYTHON_USEDEP}]
+	>=dev-python/requests-toolbelt-0.5.0[${PYTHON_USEDEP}]
+	>=dev-python/atomicwrites-0.1.7[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	dev-python/setuptools_scm[${PYTHON_USEDEP}]
+	test? (
+		>=dev-python/hypothesis-3.1[${PYTHON_USEDEP}]
+		dev-python/pytest[${PYTHON_USEDEP}]
+		dev-python/pytest-localserver[${PYTHON_USEDEP}]
+		dev-python/pytest-subtesthack[${PYTHON_USEDEP}]
+	)"
+
+DOCS=( AUTHORS.rst CHANGELOG.rst CONTRIBUTING.rst README.rst config.example )
+
+python_test() {
+	# skip tests needing servers running
+	local -x DAV_SERVER=skip
+	local -x REMOTESTORAGE_SERVER=skip
+	# pytest dies hard if the envvars do not have any value...
+	local -x CI=false
+	local -x DETERMINISTIC_TESTS=false
+	py.test -v || die "Tests fail with ${EPYTHON}"
+}