dev-ruby/regexp_parser: add 1.4.0

Signed-off-by: Hans de Graaff <graaff@gentoo.org>
Package-Manager: Portage-2.3.62, Repoman-2.3.11

1 files changed, 38 insertions, 0 deletions

diff --git a/dev-ruby/regexp_parser/regexp_parser-1.4.0.ebuild b/dev-ruby/regexp_parser/regexp_parser-1.4.0.ebuild
new file mode 100644
index 00000000000..c7be5088b5d
--- /dev/null
+++ b/dev-ruby/regexp_parser/regexp_parser-1.4.0.ebuild
@@ -0,0 +1,38 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+USE_RUBY="ruby23 ruby24 ruby25 ruby26"
+
+RUBY_FAKEGEM_RECIPE_DOC="rdoc"
+RUBY_FAKEGEM_EXTRADOC="CHANGELOG.md README.md"
+
+RUBY_FAKEGEM_BINWRAP=""
+
+inherit ruby-fakegem
+
+DESCRIPTION="A library for tokenizing, lexing, and parsing Ruby regular expressions"
+HOMEPAGE="https://github.com/ammar/regexp_parser"
+SRC_URI="https://github.com/ammar/regexp_parser/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="1"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE=""
+
+DEPEND+=" =dev-util/ragel-6*"
+
+ruby_add_bdepend "dev-ruby/rake test? ( dev-ruby/regexp_property_values )"
+
+all_ruby_prepare() {
+	sed -i -e '/bundler/I s:^:#:' Rakefile || die
+	sed -i -e '1irequire "delegate"' test/support/warning_extractor.rb || die
+}
+
+each_ruby_compile() {
+	${RUBY} -S rake ragel:rb || die
+}
+
+each_ruby_test() {
+	${RUBY} -Ilib bin/test || die
+}