gnome-extra/gnome-shell-extension-gsconnect: It really needs nautilus-python

Thanks-to: leio
Closes: https://bugs.gentoo.org/662056
Package-Manager: Portage-2.3.53, Repoman-2.3.12
Signed-off-by: Pacho Ramos <pacho@gentoo.org>

1 files changed, 56 insertions, 0 deletions

diff --git a/gnome-extra/gnome-shell-extension-gsconnect/gnome-shell-extension-gsconnect-12-r1.ebuild b/gnome-extra/gnome-shell-extension-gsconnect/gnome-shell-extension-gsconnect-12-r1.ebuild
new file mode 100644
index 00000000000..8fb81e051a8
--- /dev/null
+++ b/gnome-extra/gnome-shell-extension-gsconnect/gnome-shell-extension-gsconnect-12-r1.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit gnome2-utils meson readme.gentoo-r1
+
+DESCRIPTION="KDE Connect implementation for Gnome Shell"
+HOMEPAGE="https://github.com/andyholmes/gnome-shell-extension-gsconnect"
+SRC_URI="https://github.com/andyholmes/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="amd64"
+IUSE=""
+
+COMMON_DEPEND="dev-libs/glib:2"
+
+RDEPEND="${COMMON_DEPEND}
+	app-eselect/eselect-gnome-shell-extensions
+	>=dev-libs/gjs-1.48
+	dev-python/nautilus-python
+	>=gnome-base/gnome-shell-3.24
+	gnome-base/nautilus[introspection]
+	net-fs/sshfs
+	|| ( ( net-libs/gnome-online-accounts dev-libs/libgdata ) dev-libs/folks )
+	|| ( media-libs/libcanberra media-libs/gsound )
+"
+DEPEND="${COMMON_DEPEND}
+	virtual/pkgconfig
+"
+
+DISABLE_AUTOFORMATTING="yes"
+DOC_CONTENTS="For knowing more about how to do the setup, please visit:
+https://github.com/andyholmes/gnome-shell-extension-gsconnect/wiki/Installation"
+
+src_install() {
+	meson_src_install
+
+	# Rule for install is not complete, only works for install-zip
+	# target
+	glib-compile-schemas "${ED}"/usr/share/gnome-shell/extensions/gsconnect@andyholmes.github.io/schemas || die
+
+	readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+	gnome2_schemas_update
+	ebegin "Updating list of installed extensions"
+	eselect gnome-shell-extensions update
+	eend $?
+	readme.gentoo_print_elog
+}
+
+pkg_postrm() {
+	gnome2_schemas_update
+}