mate-base/mate-panel: 1.12.x vbump, add gtk3 support, import from project repo

Package-Manager: portage-2.3.0

3 files changed, 82 insertions, 0 deletions

diff --git a/mate-base/mate-panel/Manifest b/mate-base/mate-panel/Manifest
index 52b41cb31ab..eb67d96f89d 100644
--- a/mate-base/mate-panel/Manifest
+++ b/mate-base/mate-panel/Manifest
@@ -1 +1,2 @@
 DIST mate-panel-1.10.1.tar.xz 1934576 SHA256 261702b4eaf5339a55629c5f31466fb7878d5a640f80f88edde54ed1b9eba444 SHA512 4e8e2eddf2d9ae51b2b332dc6d96130afe90a767d1aca9cbc7a60b77f1e39d233c7a1c2490f5d68f33c6bc2fc834aee9f6cfb888c0cf3ab4b7886880865c9e95 WHIRLPOOL d07913e8b09f3e6ac095a8cc801c06b83c598d38a63dfd39f8b619e736c453dcbf50ef5bb33bcf293b262687cdba4635ea7a16bc4375842b3634ae29ef6f7a40
+DIST mate-panel-1.12.2.tar.xz 1930792 SHA256 b757bb5ea3da1b36fcf599d4f123534e936f0e46859b3307816085f486667fa1 SHA512 7810c3b3585e9def59c192914a91e2e64173b5b44cf43496808f6be46df798fc97358bb7bc300e52985fc401feb5201daad60bb0181e72e5e2512e7712aba6a4 WHIRLPOOL 2af7cdf4b38aab536497196dd8abd67583d93d915288d2a2eda67f31e9eba5030ee5360f6ad47cbc4d21389160b3209e99d84eecde1b2093ee9ce566b7cacd5a
diff --git a/mate-base/mate-panel/mate-panel-1.12.2-r3.ebuild b/mate-base/mate-panel/mate-panel-1.12.2-r3.ebuild
new file mode 100644
index 00000000000..c901debb838
--- /dev/null
+++ b/mate-base/mate-panel/mate-panel-1.12.2-r3.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+MATE_LA_PUNT="yes"
+
+inherit mate
+
+if [[ ${PV} != 9999 ]]; then
+	KEYWORDS="~amd64 ~arm ~x86"
+fi
+
+DESCRIPTION="The MATE panel"
+LICENSE="GPL-2 FDL-1.1 LGPL-2"
+SLOT="0"
+
+IUSE="X gtk3 +introspection"
+
+RDEPEND="
+	dev-libs/atk:0
+	>=dev-libs/dbus-glib-0.80:0
+	>=dev-libs/glib-2.36:2
+	>=dev-libs/libmateweather-1.7[gtk3(-)=]
+	dev-libs/libxml2:2
+	>=gnome-base/dconf-0.10:0
+	gnome-base/librsvg:2
+	>=mate-base/mate-desktop-1.9.3[gtk3(-)=]
+	>=mate-base/mate-menus-1.6
+	>=sys-apps/dbus-1.1.2:0
+	>=x11-libs/cairo-1:0
+	>=x11-libs/gdk-pixbuf-2.7.1:2
+	x11-libs/libICE:0
+	x11-libs/libSM:0
+	x11-libs/libX11:0
+	>=x11-libs/pango-1.15.4:0[introspection?]
+	x11-libs/libXau:0
+	>=x11-libs/libXrandr-1.3:0
+	virtual/libintl:0
+	!gtk3? (
+		media-libs/libcanberra:0[gtk]
+		>=x11-libs/gtk+-2.19.7:2[introspection?]
+		>=x11-libs/libwnck-2.30:1[introspection?]
+	)
+	gtk3? (
+		media-libs/libcanberra:0[gtk3]
+		>=x11-libs/gtk+-3.0:3[introspection?]
+		>=x11-libs/libwnck-3.0:3[introspection?]
+	)
+	introspection? ( >=dev-libs/gobject-introspection-0.6.7:= )"
+
+DEPEND="${RDEPEND}
+	app-text/docbook-xml-dtd:4.1.2
+	app-text/yelp-tools:0
+	>=dev-lang/perl-5:0=
+	dev-util/gtk-doc
+	dev-util/gtk-doc-am
+	>=dev-util/intltool-0.50.1:*
+	sys-devel/gettext:*
+	virtual/pkgconfig:*"
+
+MATE_FORCE_AUTORECONF=true
+
+src_prepare() {
+	# Disable python check.
+	sed -e '/AM_PATH_PYTHON/d' -i configure.ac || die
+	mate_src_prepare
+}
+
+src_configure() {
+	mate_src_configure \
+		--libexecdir=/usr/libexec/mate-applets \
+		--disable-deprecation-flags \
+		--with-gtk=$(usex gtk3 3.0 2.0) \
+		$(use_with X x) \
+		$(use_enable introspection)
+}
diff --git a/mate-base/mate-panel/metadata.xml b/mate-base/mate-panel/metadata.xml
index 0c4ac783b49..13e4aa67b30 100644
--- a/mate-base/mate-panel/metadata.xml
+++ b/mate-base/mate-panel/metadata.xml
@@ -5,6 +5,9 @@
         <email>mate@gentoo.org</email>
         <name>Gentoo MATE Desktop</name>
     </maintainer>
+	<use>
+		<flag name="gtk3">Build with GTK+3 instead of GTK+2</flag>
+	</use>
     <upstream>
         <remote-id type="github">mate-desktop/mate-panel</remote-id>
     </upstream>