media-libs/libmediainfo: version bump to 0.7.98

2 files changed, 84 insertions, 0 deletions

diff --git a/media-libs/libmediainfo/Manifest b/media-libs/libmediainfo/Manifest
index c640abdb1b9..9de8609ae40 100644
--- a/media-libs/libmediainfo/Manifest
+++ b/media-libs/libmediainfo/Manifest
@@ -1,2 +1,3 @@
 DIST libmediainfo_0.7.96.tar.xz 1597404 SHA256 fd68e334b29da7c2e1afe5664ef6678d71f00d439c2156b94388a9b481444265 SHA512 14cfe6d11038263e2f11ed9c36a8b954d0937dea9cd7401b26e90e92f2695afc81a388b674669184ecce033d681eaa9f190636d674fd230a24e1196a6ed1992b WHIRLPOOL e0a3048962bcf0d55b5e67461110a1cec1498351cd11e59bfece29a4b461f66191e3d4373a8473d2889dc2f868d8045f905063c6fd877df0e88cf7e44dfae85e
 DIST libmediainfo_0.7.97.tar.xz 1600348 SHA256 8deab3af599832818ca951bd17819bad730a6d4c2eb6dfae86249ef8f5eafd66 SHA512 b531836b8a14a60afb39afeedaa5a640e3d870372b3bdbdb4a37769dd17d3646248aa897f29da2611eb3e7aa4e6309916cbcf5b2875718996dc63c1b973e6964 WHIRLPOOL ab6b55bc7da2eac6a7dc361964b2cf43c147874a3cefb5cee5e53201999f62b92f2600d8ae7f0c2b17320d9dadaea1295744c4238c55180b81759ac97c4a265b
+DIST libmediainfo_0.7.98.tar.xz 1602452 SHA256 c442ff8e179ef0611f9af38cff550255f3307f787a03d065d14d7d6300bc05dc SHA512 d4f9021968a6bbec253ff8a178b41443df69bea07a3277f840a3a3ed1bbbfb4fc5719797692450f1cd2f70c65886f257cef4402d8a6c4a247b0f6943c49e86ea WHIRLPOOL 456916e93c0395560cf3c1a13761816c8f79151a261f8c4e9506b7c6d37e3b1c2c8fd9f69d895eac1a5b3429caab91bd2817d6f0f9ed54897f6f4bffd286e8ac
diff --git a/media-libs/libmediainfo/libmediainfo-0.7.98.ebuild b/media-libs/libmediainfo/libmediainfo-0.7.98.ebuild
new file mode 100644
index 00000000000..fb27ee39247
--- /dev/null
+++ b/media-libs/libmediainfo/libmediainfo-0.7.98.ebuild
@@ -0,0 +1,83 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit autotools eutils flag-o-matic
+
+MY_PN="MediaInfo"
+DESCRIPTION="MediaInfo libraries"
+HOMEPAGE="http://mediaarea.net/mediainfo/ https://github.com/MediaArea/MediaInfoLib"
+SRC_URI="http://mediaarea.net/download/source/${PN}/${PV}/${P/-/_}.tar.xz"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="curl doc mms static-libs"
+
+RDEPEND="sys-libs/zlib
+	dev-libs/tinyxml2:=
+	>=media-libs/libzen-0.4.34[static-libs=]
+	curl? ( net-misc/curl )
+	mms? ( >=media-libs/libmms-0.6.1[static-libs=] )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )"
+
+# tests try to fetch data from online sources
+RESTRICT="test"
+
+S=${WORKDIR}/${MY_PN}Lib/Project/GNU/Library
+
+src_prepare() {
+	eapply -p4 "${FILESDIR}"/${PN}-0.7.63-pkgconfig.patch
+	eapply_user
+
+	sed -i 's:-O2::' configure.ac || die
+	append-cppflags -DMEDIAINFO_LIBMMS_DESCRIBE_SUPPORT=0
+
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--enable-shared \
+		--with-libtinyxml2 \
+		$(use_with curl libcurl) \
+		$(use_with mms libmms) \
+		$(use_enable static-libs static) \
+		$(use_enable static-libs staticlibs)
+}
+
+src_compile() {
+	default
+
+	if use doc; then
+		cd "${WORKDIR}"/${MY_PN}Lib/Source/Doc
+		doxygen Doxyfile || die
+	fi
+}
+
+src_install() {
+	if use doc; then
+		local HTML_DOCS=( "${WORKDIR}"/${MY_PN}Lib/Doc/*.html )
+	fi
+
+	default
+
+	edos2unix ${PN}.pc #414545
+	insinto /usr/$(get_libdir)/pkgconfig
+	doins ${PN}.pc
+
+	for x in ./ Archive Audio Duplicate Export Image Multiple Reader Tag Text Video; do
+		insinto /usr/include/${MY_PN}/${x}
+		doins "${WORKDIR}"/${MY_PN}Lib/Source/${MY_PN}/${x}/*.h
+	done
+
+	insinto /usr/include/${MY_PN}DLL
+	doins "${WORKDIR}"/${MY_PN}Lib/Source/${MY_PN}DLL/*.h
+
+	dodoc "${WORKDIR}"/${MY_PN}Lib/*.txt
+
+	prune_libtool_files
+}