proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 99 insertions, 0 deletions

diff --git a/media-libs/openimageio/openimageio-1.1.7.ebuild b/media-libs/openimageio/openimageio-1.1.7.ebuild
new file mode 100644
index 00000000000..b3c62cc5004
--- /dev/null
+++ b/media-libs/openimageio/openimageio-1.1.7.ebuild
@@ -0,0 +1,99 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+PYTHON_COMPAT=( python2_7 )
+
+inherit cmake-utils eutils multilib python-single-r1 vcs-snapshot
+
+DESCRIPTION="A library for reading and writing images"
+HOMEPAGE="http://sites.google.com/site/openimageio/ http://github.com/OpenImageIO"
+SRC_URI="http://github.com/OpenImageIO/oiio/archive/Release-${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc64 ~x86"
+IUSE="jpeg2k colorio opencv opengl python qt4 tbb +truetype"
+
+RESTRICT="test" #431412
+
+RDEPEND="dev-libs/boost[python?]
+	dev-libs/pugixml:=
+	media-libs/glew:=
+	media-libs/ilmbase:=
+	media-libs/libpng:0=
+	>=media-libs/libwebp-0.2.1:=
+	media-libs/openexr:=
+	media-libs/tiff:0=
+	sci-libs/hdf5
+	sys-libs/zlib:=
+	virtual/jpeg
+	jpeg2k? ( >=media-libs/openjpeg-1.5:0= )
+	colorio? ( >=media-libs/opencolorio-1.0.7:= )
+	opencv? (
+		>=media-libs/opencv-2.3:=
+		python? ( || ( <media-libs/opencv-2.4.8 >=media-libs/opencv-2.4.8[python,${PYTHON_USEDEP}] ) )
+	)
+	opengl? (
+		virtual/glu
+		virtual/opengl
+		)
+	python? ( ${PYTHON_DEPS} )
+	qt4? (
+		dev-qt/qtcore:4
+		dev-qt/qtgui:4
+		dev-qt/qtopengl:4
+		)
+	tbb? ( dev-cpp/tbb )
+	truetype? ( media-libs/freetype:2= )"
+DEPEND="${RDEPEND}"
+
+S=${WORKDIR}/${P}/src
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	# remove bundled code to make it build
+	# https://github.com/OpenImageIO/oiio/issues/403
+	rm */pugixml* || die
+
+	# fix man page building
+	# https://github.com/OpenImageIO/oiio/issues/404
+	use qt4 || sed -i -e '/list.*APPEND.*cli_tools.*iv/d' doc/CMakeLists.txt
+
+	use python && python_fix_shebang .
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DLIB_INSTALL_DIR="/usr/$(get_libdir)"
+		-DBUILDSTATIC=OFF
+		-DLINKSTATIC=OFF
+		$(use python && echo -DPYLIB_INSTALL_DIR="$(python_get_sitedir)")
+		-DUSE_EXTERNAL_PUGIXML=ON
+		-DUSE_FIELD3D=OFF # missing in Portage
+		$(cmake-utils_use_use truetype freetype)
+		$(cmake-utils_use_use colorio OCIO)
+		$(cmake-utils_use_use opencv)
+		$(cmake-utils_use_use opengl)
+		$(cmake-utils_use_use jpeg2k OPENJPEG)
+		$(cmake-utils_use_use python)
+		$(cmake-utils_use_use qt4 QT)
+		$(cmake-utils_use_use tbb)
+		)
+
+	cmake-utils_src_configure
+}
+
+src_install() {
+	cmake-utils_src_install
+
+	rm -rf "${ED}"/usr/share/doc
+	dodoc ../{CHANGES,CREDITS,README*} # doc/CLA-{CORPORATE,INDIVIDUAL}
+	docinto pdf
+	dodoc doc/*.pdf
+}