proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

3 files changed, 93 insertions, 0 deletions

diff --git a/media-sound/alsaplayer/Manifest b/media-sound/alsaplayer/Manifest
new file mode 100644
index 00000000000..0756d391e53
--- /dev/null
+++ b/media-sound/alsaplayer/Manifest
@@ -0,0 +1 @@
+DIST alsaplayer-0.99.81.tar.bz2 806906 SHA256 187897e5ad5a94ea819e42092cc35d53463e5fa43a3a5a78cb76ffd0d5ddee11
diff --git a/media-sound/alsaplayer/alsaplayer-0.99.81.ebuild b/media-sound/alsaplayer/alsaplayer-0.99.81.ebuild
new file mode 100644
index 00000000000..b76b96cecf4
--- /dev/null
+++ b/media-sound/alsaplayer/alsaplayer-0.99.81.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=4
+inherit autotools eutils
+
+DESCRIPTION="A heavily multi-threaded pluggable audio player"
+HOMEPAGE="http://www.alsaplayer.org/"
+SRC_URI="http://www.alsaplayer.org/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="amd64 ~mips ~ppc ~sparc x86"
+IUSE="+alsa audiofile doc flac gtk id3tag jack mad mikmod nas nls ogg opengl oss vorbis xosd"
+
+RDEPEND="media-libs/libsndfile
+	sys-libs/zlib
+	alsa? ( media-libs/alsa-lib )
+	audiofile? ( media-libs/audiofile )
+	flac? ( media-libs/flac )
+	gtk? ( >=x11-libs/gtk+-2.10:2 )
+	id3tag? ( media-libs/libid3tag )
+	jack? ( >=media-sound/jack-audio-connection-kit-0.80 )
+	mad? ( media-libs/libmad )
+	mikmod? ( media-libs/libmikmod:0 )
+	nas? ( media-libs/nas )
+	ogg? ( media-libs/libogg )
+	opengl? ( virtual/opengl )
+	vorbis? ( media-libs/libvorbis )
+	xosd? ( x11-libs/xosd )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )
+	nls? ( sys-devel/gettext )
+	oss? ( virtual/os-headers )"
+REQUIRED_USE="|| ( alsa jack nas oss )"
+
+src_prepare() {
+	sed -i \
+		-e 's:AM_CFLAGS = $(AM_CXXFLAGS)::' \
+		output/jack/Makefile.am || die
+
+	sed -i \
+		-e 's:-O2 -funroll-loops -finline-functions -ffast-math::' \
+		configure.ac || die
+
+	eautoreconf
+}
+
+src_configure() {
+	use doc || export ac_cv_prog_HAVE_DOXYGEN=false
+	use xosd || export ac_cv_lib_xosd_xosd_create=no
+
+	econf \
+		--docdir=/usr/share/doc/${PF} \
+		$(use_enable nls) \
+		$(use_enable opengl) \
+		$(use_enable mikmod) \
+		$(use_enable vorbis oggvorbis) \
+		$(use_enable audiofile) \
+		$(use_enable flac) \
+		$(use_enable mad) \
+		$(use_enable id3tag) \
+		$(use_enable gtk systray) \
+		$(use_enable jack) \
+		$(use_enable alsa) \
+		--disable-esd \
+		$(use_enable oss) \
+		$(use_enable gtk gtk2) \
+		$(use_enable nas)
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+	dodoc AUTHORS ChangeLog README TODO docs/*.txt
+	newicon interface/gtk2/pixmaps/logo.xpm ${PN}.xpm
+
+	find "${ED}" -name '*.la' -exec rm -f {} +
+}
diff --git a/media-sound/alsaplayer/metadata.xml b/media-sound/alsaplayer/metadata.xml
new file mode 100644
index 00000000000..8882930edee
--- /dev/null
+++ b/media-sound/alsaplayer/metadata.xml
@@ -0,0 +1,12 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<herd>sound</herd>
+	<use>
+		<flag name="id3tag">Enables ID3 tagging with id3tag library</flag>
+	</use>
+	<maintainer>
+		<email>redhatter@gentoo.org</email>
+		<name>Stuart Longland</name>
+	</maintainer>
+</pkgmetadata>