net-mail/courier-imap: bump, set border version to courier-unicode

described in bug #553820, fixes bugs #553820 & #553720

Package-Manager: portage-2.2.20

3 files changed, 221 insertions, 1 deletions

diff --git a/net-mail/courier-imap/Manifest b/net-mail/courier-imap/Manifest
index 72b89485cbb..9ca4584e1f7 100644
--- a/net-mail/courier-imap/Manifest
+++ b/net-mail/courier-imap/Manifest
@@ -1,2 +1,3 @@
 DIST courier-imap-4.15.tar.bz2 3266353 SHA256 6c34107e7ba9e5396d50b58fb414a495806335cab7135c96ad85a3816785b109 SHA512 7829662282db5e6f414a1d34f06a94c2dd028e263510f01b49ebd3a1a4994055ecc08604568f5a44a30f6411e3a34e0d6c38807c29eaf255752191e885f82e1a WHIRLPOOL 1b5e42bd1f72e3205030b54e9564ce45c4eccb394b31c64a616f225def5a5df05f74ef62c59fbea63b18ce336d77cc2368170a982abb7a6e94d309d0c6ee4dd2
 DIST courier-imap-4.16.0.tar.bz2 3021228 SHA256 20ee63fbb5eef671dfcceecf3ed3eb48663cff3bcb607ecc904d0bc4f8c0b4b2 SHA512 5f84c035e3936cf2b435efee7ecb98f98da8ecdd3afa3661ba03737d870aa038586a49c3a696fd8d028302349279139e90b1befc1d42a8488909c0ca0ea96a5c WHIRLPOOL be8b916ff9526c0a34cbad210bb026ab176a327eba4c4e5d76da7d99e800418749b0ab50bff9ce9a7378ddfd9342a86ad3462e4418e0d36bad159ed2db3af069
+DIST courier-imap-4.16.2.tar.bz2 3028445 SHA256 3be244b3c4d3d5c5e33efb37e4cf712ae83cbe21e43c31725e0d996ab4acc387 SHA512 42a685324b630835fe0c8735a67879e099f96eadf091c803368a9dd478a80b4ab47225fda6142942569c96b21355b5dac5e174ff434bcdc78784a810d2088609 WHIRLPOOL d1d8af441a8c6f13f81705489deded11fdd8f66bf79a66f9076ed4e7b6e0644d9f9034887a043d8c9c9a55031db9c2c9a2ca0ac53cbbef96c5ed25275c50e9e3
diff --git a/net-mail/courier-imap/courier-imap-4.16.0.ebuild b/net-mail/courier-imap/courier-imap-4.16.0.ebuild
index 69952485817..df137619270 100644
--- a/net-mail/courier-imap/courier-imap-4.16.0.ebuild
+++ b/net-mail/courier-imap/courier-imap-4.16.0.ebuild
@@ -21,7 +21,7 @@ CDEPEND="
 	gnutls? ( net-libs/gnutls )
 	!gnutls? ( >=dev-libs/openssl-0.9.6:0= )
 	>=net-libs/courier-authlib-0.61
-	>=net-libs/courier-unicode-1.1
+	~net-libs/courier-unicode-1.1
 	>=net-mail/mailbase-0.00-r8
 	berkdb? ( sys-libs/db:= )
 	fam? ( virtual/fam )
diff --git a/net-mail/courier-imap/courier-imap-4.16.2.ebuild b/net-mail/courier-imap/courier-imap-4.16.2.ebuild
new file mode 100644
index 00000000000..00f353569b4
--- /dev/null
+++ b/net-mail/courier-imap/courier-imap-4.16.2.ebuild
@@ -0,0 +1,219 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+inherit autotools eutils multilib libtool systemd
+
+DESCRIPTION="An IMAP daemon designed specifically for maildirs"
+HOMEPAGE="http://www.courier-mta.org/"
+SRC_URI="mirror://sourceforge/courier/${P}.tar.bz2"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~hppa ~ppc64 ~x86"
+IUSE="berkdb debug fam +gdbm ipv6 selinux gnutls trashquota"
+
+REQUIRED_USE="|| ( berkdb gdbm )"
+
+CDEPEND="
+	gnutls? ( net-libs/gnutls )
+	!gnutls? ( >=dev-libs/openssl-0.9.6:0= )
+	>=net-libs/courier-authlib-0.61
+	>=net-libs/courier-unicode-1.3
+	>=net-mail/mailbase-0.00-r8
+	berkdb? ( sys-libs/db:= )
+	fam? ( virtual/fam )
+	gdbm? ( >=sys-libs/gdbm-1.8.0 )"
+DEPEND="${CDEPEND}
+	dev-lang/perl
+	!mail-mta/courier
+	userland_GNU? ( sys-process/procps )"
+RDEPEND="${CDEPEND}
+	selinux? ( sec-policy/selinux-courier )"
+
+# get rid of old style virtual - bug 350792
+# all blockers really needed?
+RDEPEND="${RDEPEND}
+	!mail-mta/courier
+	!net-mail/bincimap
+	!net-mail/cyrus-imapd
+	!net-mail/uw-imap"
+
+RC_VER="4.0.6-r1"
+INITD_VER="4.0.6-r1"
+
+src_prepare() {
+	# Bug #48838. Patch to enable/disable FAM support.
+	# 20 Aug 2004 langthang@gentoo.org
+	# This patch should fix bug #51540. fam USE flag is not needed for shared folder support.
+	epatch "${FILESDIR}"/${PN}-4.15-disable-fam-configure.ac.patch
+
+	# Kill unneeded call to AC_PROG_SYSCONFTOOL (bug #168206).
+	epatch "${FILESDIR}"/${PN}-4.15-aclocal-fix.patch
+
+	# These patches should fix problems detecting BerkeleyDB.
+	# We now can compile with db4 support.
+	if use berkdb ; then
+		epatch \
+			"${FILESDIR}"/${PN}-4.15-db4-bdbobj_configure.ac.patch \
+			"${FILESDIR}"/${PN}-4.15-db4-configure.ac.patch
+	fi
+
+	eautoreconf
+}
+
+src_configure() {
+	local myconf=""
+
+	# 19 Aug 2004 langthang@gentoo.org
+	# Default to gdbm if both berkdb and gdbm are present.
+	if use gdbm ; then
+		einfo "Building with GDBM support"
+		myconf="${myconf} --with-db=gdbm"
+	elif use berkdb ; then
+		einfo "Building with BerkeleyDB support"
+		myconf="${myconf} --with-db=db"
+	fi
+
+	if use trashquota ; then
+		einfo "Building with Trash Quota Support"
+		myconf="${myconf} --with-trashquota"
+	fi
+
+	use debug && myconf="${myconf} debug=true"
+
+	# Do the actual build now
+	econf \
+		--disable-root-check \
+		--bindir=/usr/sbin \
+		--sysconfdir=/etc/${PN} \
+		--libexecdir=/usr/$(get_libdir)/${PN} \
+		--localstatedir=/var/lib/${PN} \
+		--with-authdaemonvar=/var/lib/${PN}/authdaemon \
+		--enable-workarounds-for-imap-client-bugs \
+		--with-mailuser=mail \
+		--with-mailgroup=mail \
+		$(use_with fam) \
+		$(use_with ipv6) \
+		$(use_with gnutls) \
+		${myconf}
+
+	# Change the pem file location.
+	sed -i -e "s:^\(TLS_CERTFILE=\).*:\1/etc/courier-imap/imapd.pem:" \
+		libs/imap/imapd-ssl.dist || \
+		die "sed failed"
+
+	sed -i -e "s:^\(TLS_CERTFILE=\).*:\1/etc/courier-imap/pop3d.pem:" \
+		libs/imap/pop3d-ssl.dist || \
+		die "sed failed"
+}
+
+src_compile() {
+	# spurious failures with parallel compiles
+	emake -j1
+}
+
+src_install() {
+	dodir /var/lib/${PN} /etc/pam.d
+	default
+	rm -Rf "${D}/etc/pam.d" || die
+
+	# Avoid name collisions in /usr/sbin wrt imapd and pop3d
+	cd "${D}/usr/sbin" || die
+	for name in imapd pop3d ; do
+		mv -f "${name}" "courier-${name}" || die "Failed to mv ${name} to courier-${name}"
+	done
+
+	# Hack /usr/lib/courier-imap/foo.rc to use ${MAILDIR} instead of
+	# 'Maildir', and to use /usr/sbin/courier-foo names.
+	cd "${D}/usr/$(get_libdir)/${PN}" || die
+	for service in {imapd,pop3d}{,-ssl} ; do
+		sed -i -e 's/Maildir/${MAILDIR}/' "${service}.rc" || die "sed failed"
+		sed -i -e "s/\/usr\/sbin\/${service}/\/usr\/sbin\/courier-${service}/" "${service}.rc" || die "sed failed"
+	done
+
+	# Rename the config files correctly and add a value for ${MAILDIR} to them.
+	cd "${D}/etc/${PN}" || die
+	for service in {imapd,pop3d}{,-ssl} ; do
+		mv -f "${service}.dist" "${service}" || die "Failed to mv ${service}.dist to ${service}"
+		echo -e '\n# Hardwire a value for ${MAILDIR}' >> "${service}"
+		echo 'MAILDIR=.maildir' >> "${service}"
+		echo 'MAILDIRPATH=.maildir' >> "${service}"
+	done
+	for service in imapd pop3d ; do
+		echo -e '# Put any program for ${PRERUN} here' >> "${service}"
+		echo 'PRERUN=' >> "${service}"
+		echo -e '# Put any program for ${LOGINRUN} here' >> "${service}"
+		echo -e '# this is for relay-ctrl-allow in 4*' >> "${service}"
+		echo 'LOGINRUN=' >> "${service}"
+	done
+
+	cd "${D}/usr/sbin"
+	for x in * ; do
+		if [[ -L "${x}" ]] ; then
+			rm -f "${x}" || die "Failed to rm ${x}"
+		fi
+	done
+
+	cd ../share
+	mv -f * ../sbin
+	mv -f ../sbin/man .
+	cd ..
+
+	for x in mkimapdcert mkpop3dcert ; do
+		mv -f "${D}/usr/sbin/${x}" "${D}/usr/sbin/${x}.orig" || die "Failed to mv /usr/sbin/${x} to /usr/sbin/${x}.orig"
+	done
+
+	dosbin "${FILESDIR}/mkimapdcert" "${FILESDIR}/mkpop3dcert"
+
+	dosym /usr/sbin/courierlogger /usr/$(get_libdir)/${PN}/courierlogger
+
+	mkdir "${WORKDIR}/tmp" ; cd "${WORKDIR}/tmp"
+
+	for initd in courier-{imapd,pop3d}{,-ssl} ; do
+		sed -e "s:GENTOO_LIBDIR:$(get_libdir):g" "${FILESDIR}/${PN}-${INITD_VER}-${initd}.rc6" > "${initd}" || die "initd libdir-sed failed"
+		doinitd "${initd}"
+	done
+
+	systemd_newunit "${FILESDIR}"/courier-authdaemond-r1.service courier-authdaemond.service
+	systemd_newunit "${FILESDIR}"/courier-imapd-ssl-r1.service courier-imapd-ssl.service
+	systemd_newunit "${FILESDIR}"/courier-imapd-r1.service courier-imapd.service
+
+	exeinto /usr/$(get_libdir)/${PN}
+	for exe in gentoo-{imapd,pop3d}{,-ssl}.rc courier-{imapd,pop3d}.indirect ; do
+		sed -e "s:GENTOO_LIBDIR:$(get_libdir):g" "${FILESDIR}/${PN}-${RC_VER}-${exe}" > "${exe}" || die "exe libdir-sed failed"
+		doexe "${exe}"
+	done
+
+	dodir /usr/bin
+	mv -f "${D}/usr/sbin/maildirmake" "${D}/usr/bin/maildirmake" || die "Failed to mv /usr/sbin/maildirmake to /usr/bin/maildirmake"
+
+	# Bug #45953, more docs.
+	cd "${S}" || die
+	dohtml -r "${S}"/*
+	dodoc "${S}"/{AUTHORS,INSTALL,NEWS,README,ChangeLog} "${FILESDIR}"/${PN}-gentoo.readme
+	docinto imap
+	dodoc "${S}"/libs/imap/{ChangeLog,BUGS,BUGS.html,README}
+	docinto maildir
+	dodoc "${S}"/libs/maildir/{AUTHORS,INSTALL,README.maildirquota.txt,README.sharedfolders.txt}
+	docinto tcpd
+	dodoc "${S}"/libs/tcpd/README.couriertls
+}
+
+pkg_postinst() {
+	elog "Please read http://www.courier-mta.org/imap/INSTALL.html#upgrading"
+	elog "and remove TLS_DHPARAMS from configuration files or run mkdhparams"
+
+	elog "For a quick-start howto please refer to"
+	elog "${PN}-gentoo.readme in /usr/share/doc/${PF}"
+	# Some users have been reporting that permissions on this directory were
+	# getting scrambled, so let's ensure that they are sane.
+	chmod 0755 "${ROOT}/usr/$(get_libdir)/${PN}" || die "Failed to ensure sane permissions on ${ROOT}/usr/$(get_libdir)/${PN}"
+}
+
+src_test() {
+	ewarn "make check is not supported by this package due to the"
+	ewarn "--enable-workarounds-for-imap-client-bugs option."
+}