net-misc/flexget: Bump to 1.2.346 and adjust sqlalchemy dep

Package-Manager: portage-2.2.20

3 files changed, 78 insertions, 1 deletions

diff --git a/net-misc/flexget/Manifest b/net-misc/flexget/Manifest
index b78d00a67f8..0f85c593634 100644
--- a/net-misc/flexget/Manifest
+++ b/net-misc/flexget/Manifest
@@ -2,3 +2,4 @@ DIST FlexGet-1.2.141.tar.gz 953248 SHA256 e2d012cbe6bd49def515c7066b8ef42aa4067b
 DIST FlexGet-1.2.192.tar.gz 971176 SHA256 17fcf943f9a5ee8e03de49c716874260883393cc5a827a2f52ab1d437f84993a SHA512 7b16bc2f6db7fd314c8af0cfacdabbb85839e134c8add4554db104e27f0e26da7670b7f0b900753084553e9b32a83117c6493867445747c009c539532e28dddf WHIRLPOOL 3a0cf02f0a763057f634ece54f17aaf9d11fd96aa37da65de05f217cbaf3c8c5642fc3f5c32557ffbfefb761fe734bced98aeb76aaf2040aca5813b6aa1cceec
 DIST FlexGet-1.2.247.tar.gz 855985 SHA256 7bd487bb113fc43afc0f7330102431475697be307b9a61a84273c8dc4a1b32de SHA512 9fccb9708fac89844c396a30c1a1730fb5fd8401aabf7cdae1fe4bce76dc505a7671c1113c714bc581844020e0180fca59b76371258ebcf853ba80db7d9062ae WHIRLPOOL 54e3f96d1c52bd96fd545ab126d9582dfa11fdaeccf17d22f17be5e6f6ad74008f320e8919308113028ef05ebc4d6f1194acb1f3e330362c6d196bfc4710fdcd
 DIST FlexGet-1.2.315.tar.gz 885048 SHA256 eae388a8f30096c6eb54ee96509e418d3e2633d05cbef9517a4c94607cdddafa SHA512 65d11bf568eaaa043dea2911dda63e21b2fcb648efef6e7c7a1d9976ad1901f2d3771d4ced21212c14c2b52674b64bfd9654412619e75d7f66fe797264cd51c2 WHIRLPOOL b88491c329130f75c1cffad9ada73c582f4795ec4fdd28aff9a50a25b8a8ef5a6e7f576855c0b2d52759a40861342c745a44ab12e56248fc1b55ef83ebb8a32b
+DIST FlexGet-1.2.346.tar.gz 894866 SHA256 0dc4daae0b77959cf886dbbf9d29864797472f532d8eb593909c551589c4485d SHA512 8c40043cf3cdecd42e48eb8cea23f91119459516119973135bedfc5dfea7c0018ce656755e9c3536d5d0c2f1f44e8ab1d895eea382e5106c4545d4aa457eb40e WHIRLPOOL 9ecd142de79265f05b7494944d0e9c8cddadb7624ca0ba560b4fb66c76e4a5c8b1dd124b2ca098ba6e289cd1caec08c8954e4d702cff103d784d7895a5058fae
diff --git a/net-misc/flexget/flexget-1.2.346.ebuild b/net-misc/flexget/flexget-1.2.346.ebuild
new file mode 100644
index 00000000000..16bf2175193
--- /dev/null
+++ b/net-misc/flexget/flexget-1.2.346.ebuild
@@ -0,0 +1,76 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+PYTHON_COMPAT=( python2_7 )
+
+inherit distutils-r1 eutils
+
+if [[ ${PV} != 9999 ]]; then
+	MY_P="FlexGet-${PV}"
+	SRC_URI="mirror://pypi/F/FlexGet/${MY_P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+else
+	inherit git-r3
+	EGIT_REPO_URI="git://github.com/Flexget/Flexget.git
+		https://github.com/Flexget/Flexget.git"
+fi
+
+DESCRIPTION="Multipurpose automation tool for content like torrents, nzbs, podcasts, comics"
+HOMEPAGE="http://flexget.com/"
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="test transmission"
+
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	>=dev-python/feedparser-5.1.3[${PYTHON_USEDEP}]
+	>=dev-python/sqlalchemy-0.7.5[${PYTHON_USEDEP}]
+	<dev-python/sqlalchemy-1.999[${PYTHON_USEDEP}]
+	dev-python/pyyaml[${PYTHON_USEDEP}]
+	>=dev-python/beautifulsoup-4.1:4[${PYTHON_USEDEP}]
+	<dev-python/beautifulsoup-4.4:4[${PYTHON_USEDEP}]
+	!~dev-python/beautifulsoup-4.2.0
+	>=dev-python/html5lib-0.11[${PYTHON_USEDEP}]
+	dev-python/PyRSS2Gen[${PYTHON_USEDEP}]
+	dev-python/pynzb[${PYTHON_USEDEP}]
+	dev-python/progressbar[${PYTHON_USEDEP}]
+	dev-python/rpyc[${PYTHON_USEDEP}]
+	dev-python/jinja[${PYTHON_USEDEP}]
+	>=dev-python/requests-1.0[${PYTHON_USEDEP}]
+	<dev-python/requests-2.99[${PYTHON_USEDEP}]
+	>=dev-python/python-dateutil-2.1[${PYTHON_USEDEP}]
+	!~dev-python/python-dateutil-2.2
+	>=dev-python/jsonschema-2.0[${PYTHON_USEDEP}]
+	dev-python/python-tvrage[${PYTHON_USEDEP}]
+	dev-python/tmdb3[${PYTHON_USEDEP}]
+	dev-python/path-py[${PYTHON_USEDEP}]
+	>=dev-python/guessit-0.9.3[${PYTHON_USEDEP}]
+	dev-python/APScheduler[${PYTHON_USEDEP}]
+"
+RDEPEND="${DEPEND}
+	transmission? ( dev-python/transmissionrpc[${PYTHON_USEDEP}] )
+"
+DEPEND+=" test? ( dev-python/nose[${PYTHON_USEDEP}] )"
+
+if [[ ${PV} == 9999 ]]; then
+	DEPEND+=" dev-python/paver[${PYTHON_USEDEP}]"
+else
+	S="${WORKDIR}/${MY_P}"
+fi
+
+python_prepare_all() {
+	# Prevent setup from grabbing nose from pypi
+	sed -e /setup_requires/d -i pavement.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	cp -lr tests setup.cfg "${BUILD_DIR}" || die
+	run_in_build_dir nosetests -v --attr=!online > "${T}/tests-${EPYTHON}.log" \
+		|| die "Tests fail with ${EPYTHON}"
+}
diff --git a/net-misc/flexget/flexget-9999.ebuild b/net-misc/flexget/flexget-9999.ebuild
index 6e44c092d62..16bf2175193 100644
--- a/net-misc/flexget/flexget-9999.ebuild
+++ b/net-misc/flexget/flexget-9999.ebuild
@@ -29,7 +29,7 @@ DEPEND="
 	dev-python/setuptools[${PYTHON_USEDEP}]
 	>=dev-python/feedparser-5.1.3[${PYTHON_USEDEP}]
 	>=dev-python/sqlalchemy-0.7.5[${PYTHON_USEDEP}]
-	<dev-python/sqlalchemy-0.9.99
+	<dev-python/sqlalchemy-1.999[${PYTHON_USEDEP}]
 	dev-python/pyyaml[${PYTHON_USEDEP}]
 	>=dev-python/beautifulsoup-4.1:4[${PYTHON_USEDEP}]
 	<dev-python/beautifulsoup-4.4:4[${PYTHON_USEDEP}]