net-misc/socat: Add USE=libressl (bug #565244 by Marek Behun).

Package-Manager: portage-2.2.24

3 files changed, 65 insertions, 6 deletions

diff --git a/net-misc/socat/socat-1.7.3.0-r1.ebuild b/net-misc/socat/socat-1.7.3.0-r1.ebuild
new file mode 100644
index 00000000000..6c441a2df87
--- /dev/null
+++ b/net-misc/socat/socat-1.7.3.0-r1.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+inherit eutils flag-o-matic toolchain-funcs
+
+DESCRIPTION="Multipurpose relay (SOcket CAT)"
+HOMEPAGE="http://www.dest-unreach.org/socat/"
+MY_P=${P/_beta/-b}
+S="${WORKDIR}/${MY_P}"
+SRC_URI="http://www.dest-unreach.org/socat/download/${MY_P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos"
+IUSE="libressl ssl readline ipv6 tcpd"
+
+DEPEND="
+	ssl? (
+		!libressl? ( dev-libs/openssl:* )
+		libressl? ( dev-libs/libressl )
+	)
+	readline? ( sys-libs/readline:= )
+	tcpd? ( sys-apps/tcp-wrappers )
+"
+RDEPEND="${DEPEND}"
+
+RESTRICT="test"
+
+DOCS=(
+	BUGREPORTS CHANGES DEVELOPMENT EXAMPLES FAQ FILES PORTING README SECURITY
+)
+
+src_prepare() {
+	epatch "${FILESDIR}"/${P}-filan-build.patch
+}
+
+src_configure() {
+	filter-flags '-Wno-error*' #293324
+	tc-export AR
+	econf \
+		$(use_enable ssl openssl) \
+		$(use_enable readline) \
+		$(use_enable ipv6 ip6) \
+		$(use_enable tcpd libwrap)
+}
+
+src_install() {
+	default
+
+	dohtml doc/*.html doc/*.css
+}
diff --git a/net-misc/socat/socat-2.0.0_beta8.ebuild b/net-misc/socat/socat-2.0.0_beta8.ebuild
index eb6735580dc..783b5eb40a3 100644
--- a/net-misc/socat/socat-2.0.0_beta8.ebuild
+++ b/net-misc/socat/socat-2.0.0_beta8.ebuild
@@ -15,11 +15,14 @@ SRC_URI="http://www.dest-unreach.org/socat/download/${MY_P}.tar.bz2"
 LICENSE="GPL-2"
 SLOT="0"
 KEYWORDS=""
-IUSE="ssl readline ipv6 tcpd"
+IUSE="libressl ssl readline ipv6 tcpd"
 
 DEPEND="
-	ssl? ( >=dev-libs/openssl-0.9.6 )
-	readline? ( >=sys-libs/readline-4.1 )
+	ssl? (
+		!libressl? ( dev-libs/openssl:* )
+		libressl? ( dev-libs/libressl:= )
+	)
+	readline? ( sys-libs/readline:= )
 	tcpd? ( sys-apps/tcp-wrappers )
 "
 RDEPEND="${DEPEND}"
diff --git a/net-misc/socat/socat-9999.ebuild b/net-misc/socat/socat-9999.ebuild
index e931a19da14..999d4ac6122 100644
--- a/net-misc/socat/socat-9999.ebuild
+++ b/net-misc/socat/socat-9999.ebuild
@@ -14,11 +14,14 @@ EGIT_REPO_URI="git://repo.or.cz/${PN}.git"
 LICENSE="GPL-2"
 SLOT="0"
 KEYWORDS=""
-IUSE="ssl readline ipv6 tcpd"
+IUSE="libressl ssl readline ipv6 tcpd"
 
 RDEPEND="
-	ssl? ( >=dev-libs/openssl-0.9.6 )
-	readline? ( >=sys-libs/readline-4.1 )
+	ssl? (
+		!libressl? ( dev-libs/openssl:* )
+		libressl? ( dev-libs/libressl )
+	)
+	readline? ( sys-libs/readline:= )
 	tcpd? ( sys-apps/tcp-wrappers )
 "
 DEPEND="