proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 81 insertions, 0 deletions

diff --git a/net-p2p/qbittorrent/qbittorrent-9999.ebuild b/net-p2p/qbittorrent/qbittorrent-9999.ebuild
new file mode 100644
index 00000000000..5ae750bcc86
--- /dev/null
+++ b/net-p2p/qbittorrent/qbittorrent-9999.ebuild
@@ -0,0 +1,81 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+PYTHON_COMPAT=( python2_7 )
+
+inherit eutils python-r1 qt4-r2
+
+DESCRIPTION="BitTorrent client in C++ and Qt"
+HOMEPAGE="http://www.qbittorrent.org/"
+
+MY_P=${P/_}
+if [[ ${PV} == *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/${PN}/qBittorrent.git"
+else
+	SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.xz"
+	KEYWORDS="~amd64 ~arm ~ppc64 ~x86"
+fi
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="+dbus debug +qt4 qt5 webui +X"
+REQUIRED_USE="
+	^^ ( qt4 qt5 )
+	dbus? ( X )
+"
+
+CDEPEND="
+	dev-libs/boost:=
+	>=dev-qt/qtsingleapplication-2.6.1_p20130904-r1[qt4?,qt5?,X?]
+	>=net-libs/rb_libtorrent-1.0.0
+	sys-libs/zlib
+	qt4? (
+		dev-qt/qtcore:4
+		dbus? ( dev-qt/qtdbus:4 )
+		X? ( dev-qt/qtgui:4 )
+	)
+	qt5? (
+		dev-qt/linguist-tools:5
+		dev-qt/qtcore:5
+		dev-qt/qtnetwork:5
+		dev-qt/qtxml:5
+		dbus? ( dev-qt/qtdbus:5 )
+		X? ( dev-qt/qtgui:5
+			dev-qt/qtwidgets:5 )
+	)
+"
+DEPEND="${CDEPEND}
+	virtual/pkgconfig
+"
+RDEPEND="${CDEPEND}
+	${PYTHON_DEPS}"
+
+S=${WORKDIR}/${MY_P}
+DOCS=(AUTHORS Changelog README.md TODO)
+
+src_prepare() {
+	epatch_user
+	qt4-r2_src_prepare
+}
+
+src_configure() {
+	# Custom configure script, econf fails
+	local myconf=(
+		./configure
+		--prefix="${EPREFIX}/usr"
+		--with-qtsingleapplication=system
+		$(use dbus  || echo --disable-qt-dbus)
+		$(use debug && echo --enable-debug)
+		$(use qt5   && echo --with-qt5)
+		$(use webui || echo --disable-webui)
+		$(use X     || echo --disable-gui)
+	)
+
+	echo "${myconf[@]}"
+	"${myconf[@]}" || die "configure failed"
+	use qt4 && eqmake4
+	use qt5 && eqmake5
+}