1 files changed, 56 insertions, 0 deletions
diff --git a/dev-cpp/cairomm/cairomm-1.10.0-r1.ebuild b/dev-cpp/cairomm/cairomm-1.10.0-r1.ebuild
new file mode 100644
index 00000000000..3aa2f263ddd
--- /dev/null
+++ b/dev-cpp/cairomm/cairomm-1.10.0-r1.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+GCONF_DEBUG="no"
+
+inherit eutils gnome2 multilib-minimal
+
+DESCRIPTION="C++ bindings for the Cairo vector graphics library"
+HOMEPAGE="http://cairographics.org/cairomm"
+SRC_URI="http://cairographics.org/releases/${P}.tar.gz"
+
+LICENSE="LGPL-2+"
+SLOT="0"
+KEYWORDS="alpha amd64 arm hppa ia64 ppc ppc64 ~sh sparc x86 ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos ~x86-solaris"
+IUSE="doc +svg"
+
+# FIXME: svg support is automagic
+COMMON_DEPEND="
+	>=x11-libs/cairo-1.12.10[svg?,${MULTILIB_USEDEP}]
+	>=dev-libs/libsigc++-2.3.2:2[${MULTILIB_USEDEP}]
+"
+RDEPEND="${COMMON_DEPEND}
+	abi_x86_32? (
+		!<=app-emulation/emul-linux-x86-gtkmmlibs-20140508
+		!app-emulation/emul-linux-x86-gtkmmlibs[-abi_x86_32(-)] )
+"
+DEPEND="${COMMON_DEPEND}
+	virtual/pkgconfig
+	doc? (
+		app-doc/doxygen
+		dev-libs/libxslt
+		media-gfx/graphviz )
+"
+
+src_prepare() {
+	# don't waste time building examples because they are marked as "noinst"
+	sed -i 's/^\(SUBDIRS =.*\)examples\(.*\)$/\1\2/' Makefile.in || die
+
+	# don't waste time building tests
+	# they require the boost Unit Testing framework, that's not in base boost
+	sed -i 's/^\(SUBDIRS =.*\)tests\(.*\)$/\1\2/' Makefile.in || die
+
+	gnome2_src_prepare
+}
+
+multilib_src_configure() {
+	ECONF_SOURCE="${S}" gnome2_src_configure \
+		--disable-tests \
+		$(multilib_native_use_enable doc documentation)
+}
+
+multilib_src_install() {
+	gnome2_src_install
+}