1 files changed, 44 insertions, 0 deletions
diff --git a/dev-php/pecl-dbase/pecl-dbase-7.0.0_beta1.ebuild b/dev-php/pecl-dbase/pecl-dbase-7.0.0_beta1.ebuild
new file mode 100644
index 00000000000..f0480a3595b
--- /dev/null
+++ b/dev-php/pecl-dbase/pecl-dbase-7.0.0_beta1.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+# Define 5.6 here so we get the USE and REQUIRED_USE from the eclass
+# This allows us to depend on the other slot
+USE_PHP="php5-6 php7-0 php7-1"
+
+inherit php-ext-pecl-r3
+
+# However, we only really build for 7.x; so redefine it here
+USE_PHP="php7-0 php7-1"
+
+KEYWORDS="~amd64 ~x86"
+
+DESCRIPTION="dBase database file access functions"
+LICENSE="PHP-3.01"
+SLOT="7"
+IUSE=""
+
+DEPEND=""
+RDEPEND="${DEPEND} php_targets_php5-6? ( dev-php/pecl-dbase:0[php_targets_php5-6] )"
+
+src_prepare() {
+	if use php_targets_php7-0 || use php_targets_php7-1 ; then
+		php-ext-source-r3_src_prepare
+	else
+		eapply_user
+	fi
+}
+
+src_configure() {
+	if use php_targets_php7-0 || use php_targets_php7-1 ; then
+		local PHP_EXT_ECONF_ARGS=( )
+		php-ext-source-r3_src_configure
+	fi
+}
+
+src_install() {
+	if use php_targets_php7-0 || use php_targets_php7-1 ; then
+		php-ext-pecl-r3_src_install
+	fi
+}