1 files changed, 43 insertions, 0 deletions
diff --git a/dev-python/apsw/apsw-3.11.1_p1.ebuild b/dev-python/apsw/apsw-3.11.1_p1.ebuild
new file mode 100644
index 00000000000..de24957145a
--- /dev/null
+++ b/dev-python/apsw/apsw-3.11.1_p1.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+PYTHON_COMPAT=( python{2_7,3_3,3_4,3_5} )
+
+inherit distutils-r1 flag-o-matic
+
+MY_PV=${PV/_p/-r}
+MY_P=${PN}-${MY_PV}
+
+DESCRIPTION="APSW - Another Python SQLite Wrapper"
+HOMEPAGE="https://github.com/rogerbinns/apsw/"
+SRC_URI="https://github.com/rogerbinns/apsw/releases/download/${MY_PV}/${MY_P}.zip -> ${P}.zip"
+
+LICENSE="ZLIB"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc64 ~x86"
+IUSE="doc"
+
+RDEPEND=">=dev-db/sqlite-${PV%_p*}"
+DEPEND="${RDEPEND}
+	app-arch/unzip"
+
+S=${WORKDIR}/${MY_P}
+
+PATCHES=( "${FILESDIR}/${PN}-3.6.20.1-fix_tests.patch" )
+
+python_compile() {
+	python_is_python3 || append-cflags -fno-strict-aliasing
+	distutils-r1_python_compile --enable=load_extension
+}
+
+python_test() {
+	"${PYTHON}" setup.py build_test_extension || die "Building of test loadable extension failed"
+	"${PYTHON}" tests.py -v || die "Tests failed under ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( doc/. )
+	distutils-r1_python_install_all
+}