1 files changed, 40 insertions, 0 deletions
diff --git a/dev-python/astroid/astroid-1.3.8.ebuild b/dev-python/astroid/astroid-1.3.8.ebuild
new file mode 100644
index 00000000000..8575c7b4d1d
--- /dev/null
+++ b/dev-python/astroid/astroid-1.3.8.ebuild
@@ -0,0 +1,40 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+PYTHON_COMPAT=( python2_7 python3_{3,4} pypy )
+
+inherit distutils-r1
+
+DESCRIPTION="Abstract Syntax Tree for logilab packages"
+HOMEPAGE="http://bitbucket.org/logilab/astroid http://pypi.python.org/pypi/astroid"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x64-macos ~x86-macos"
+IUSE="test"
+
+# Version specified in __pkginfo__.py.
+RDEPEND="
+	>=dev-python/logilab-common-0.63.0[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]"
+DEPEND="
+	app-arch/unzip
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		${RDEPEND}
+		>=dev-python/pylint-1.4.0[${PYTHON_USEDEP}]
+		dev-python/pytest[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep 'dev-python/egenix-mx-base[${PYTHON_USEDEP}]' python2_7)
+	)"
+# Required for tests
+DISTUTILS_IN_SOURCE_BUILD=1
+
+python_test() {
+	pushd build/lib > /dev/null || die
+	PYTHONPATH=. pytest || die "Tests fail with ${EPYTHON}"
+	popd > /dev/null || die
+}