1 files changed, 65 insertions, 0 deletions
diff --git a/dev-python/astropy/astropy-0.3.2.ebuild b/dev-python/astropy/astropy-0.3.2.ebuild
new file mode 100644
index 00000000000..50f2cbdc193
--- /dev/null
+++ b/dev-python/astropy/astropy-0.3.2.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+PYTHON_COMPAT=( python{2_7,3_3} )
+
+inherit distutils-r1
+
+DESCRIPTION="Core functionality for performing astrophysics with Python"
+HOMEPAGE="http://astropy.org/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc test"
+
+RDEPEND="
+	dev-libs/expat:0=
+	dev-python/numpy[${PYTHON_USEDEP}]
+	sci-astronomy/erfa:0=
+	sci-astronomy/wcslib:0=
+	>=sci-libs/cfitsio-3.350:0=
+	sys-libs/zlib:0="
+DEPEND="${RDEPEND}
+	dev-python/cython[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	virtual/pkgconfig
+	doc? (
+		dev-python/matplotlib[${PYTHON_USEDEP}]
+		dev-python/sphinx[${PYTHON_USEDEP}]
+		media-gfx/graphviz
+	)
+	test? (
+		dev-libs/libxml2
+		dev-python/h5py[${PYTHON_USEDEP}]
+		dev-python/matplotlib[${PYTHON_USEDEP}]
+		dev-python/pytest[${PYTHON_USEDEP}]
+		sci-libs/scipy[${PYTHON_USEDEP}]
+	)"
+
+python_compile() {
+	distutils-r1_python_compile --use-system-libraries
+}
+
+python_compile_all() {
+	if use doc; then
+		python_export_best
+		VARTEXFONTS="${T}"/fonts \
+			MPLCONFIGDIR="${BUILD_DIR}" \
+			PYTHONPATH="${BUILD_DIR}"/lib \
+			esetup.py build_sphinx
+	fi
+}
+
+python_test() {
+	esetup.py test
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/_build/html/. )
+	distutils-r1_python_install_all
+}