1 files changed, 53 insertions, 0 deletions
diff --git a/dev-python/botocore/botocore-1.1.5.ebuild b/dev-python/botocore/botocore-1.1.5.ebuild
new file mode 100644
index 00000000000..a9e058563f4
--- /dev/null
+++ b/dev-python/botocore/botocore-1.1.5.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+PYTHON_COMPAT=( python2_7 python3_3 python3_4 )
+
+inherit distutils-r1 vcs-snapshot
+
+DESCRIPTION="Low-level, data-driven core of boto 3."
+HOMEPAGE="https://github.com/boto/botocore"
+SRC_URI="https://github.com/boto/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="doc test"
+
+CDEPEND="
+	>=dev-python/docutils-0.10[${PYTHON_USEDEP}]
+	~dev-python/jmespath-0.7.1[${PYTHON_USEDEP}]
+	>=dev-python/python-dateutil-2.1[${PYTHON_USEDEP}]
+	<dev-python/python-dateutil-3.0.0[${PYTHON_USEDEP}]
+"
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? (
+		>=dev-python/guzzle_sphinx_theme-0.7.10[${PYTHON_USEDEP}]
+		<dev-python/guzzle_sphinx_theme-0.8[${PYTHON_USEDEP}]
+		>=dev-python/sphinx-1.1.3[${PYTHON_USEDEP}]
+		<dev-python/sphinx-1.3[${PYTHON_USEDEP}]
+	)
+	test? (
+		${CDEPEND}
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/nose[${PYTHON_USEDEP}]
+	)
+"
+RDEPEND="${CDEPEND}"
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_test() {
+	nosetests tests/unit || die "tests failed under ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/build/html/. )
+
+	distutils-r1_python_install_all
+}