1 files changed, 42 insertions, 0 deletions
diff --git a/dev-python/cairocffi/cairocffi-0.5.3-r1.ebuild b/dev-python/cairocffi/cairocffi-0.5.3-r1.ebuild
new file mode 100644
index 00000000000..02d50b7bc55
--- /dev/null
+++ b/dev-python/cairocffi/cairocffi-0.5.3-r1.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+PYTHON_COMPAT=( python{2_7,3_3,3_4} )
+
+inherit distutils-r1
+
+DESCRIPTION="CFFI-based drop-in replacement for Pycairo"
+MY_PN="${PN}"
+MY_P="${MY_PN}-${PV}"
+SRC_URI="mirror://pypi/${MY_P:0:1}/${MY_PN}/${MY_P}.tar.gz"
+HOMEPAGE="https://github.com/SimonSapin/cairocffi"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc test"
+
+RDEPEND=">=dev-python/cffi-0.6:=[${PYTHON_USEDEP}]
+	x11-libs/cairo:0="
+DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	test? ( dev-python/pytest[${PYTHON_USEDEP}] )"
+
+PATCHES=( "${FILESDIR}"/mapping.patch )
+
+S="${WORKDIR}/${MY_P}"
+
+python_compile_all() {
+	use doc && esetup.py build_sphinx
+}
+
+python_test() {
+	py.test ${PN}/ || die "testsuite failed under ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && HTML_DOCS=( docs/_build/html/. )
+	distutils-r1_python_install_all
+}