1 files changed, 45 insertions, 0 deletions
diff --git a/dev-python/cheetah/cheetah-2.4.4-r1.ebuild b/dev-python/cheetah/cheetah-2.4.4-r1.ebuild
new file mode 100644
index 00000000000..f2c46dc3c52
--- /dev/null
+++ b/dev-python/cheetah/cheetah-2.4.4-r1.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+PYTHON_COMPAT=( python2_7 )
+
+inherit distutils-r1
+
+MY_PN="Cheetah"
+MY_P="${MY_PN}-${PV/_}"
+
+DESCRIPTION="Python-powered template engine and code generator"
+HOMEPAGE="http://www.cheetahtemplate.org/ http://rtyler.github.com/cheetah/ http://pypi.python.org/pypi/Cheetah"
+SRC_URI="mirror://pypi/${MY_P:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+LICENSE="MIT"
+IUSE=""
+KEYWORDS="alpha amd64 ~arm ia64 ppc sparc x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos"
+SLOT="0"
+
+RDEPEND="dev-python/markdown[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]"
+
+S="${WORKDIR}/${MY_P}"
+
+DOCS=( CHANGES README.markdown TODO )
+# Race in the test suite
+DISTUTILS_IN_SOURCE_BUILD=1
+
+python_prepare_all() {
+	# Disable broken tests.
+	sed \
+		-e "/Unicode/d" \
+		-e "s/if not sys.platform.startswith('java'):/if False:/" \
+		-e "/results =/a\\    sys.exit(not results.wasSuccessful())" \
+		-i cheetah/Tests/Test.py || die "sed failed"
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	"${PYTHON}" cheetah/Tests/Test.py || die "Testing failed with ${EPYTHON}"
+}