1 files changed, 44 insertions, 0 deletions
diff --git a/dev-python/cssselect/cssselect-0.9.1.ebuild b/dev-python/cssselect/cssselect-0.9.1.ebuild
new file mode 100644
index 00000000000..e2aaeb386f3
--- /dev/null
+++ b/dev-python/cssselect/cssselect-0.9.1.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+PYTHON_COMPAT=( python{2_7,3_3,3_4} )
+
+inherit distutils-r1
+
+DESCRIPTION="parses CSS3 Selectors and translates them to XPath 1.0"
+HOMEPAGE="http://packages.python.org/cssselect/ http://pypi.python.org/pypi/cssselect"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="alpha amd64 arm ~hppa ia64 ppc ppc64 ~s390 ~sh sparc x86 ~x86-fbsd"
+IUSE="doc test"
+
+DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	test? ( dev-python/lxml[${PYTHON_USEDEP}] )"
+RDEPEND=""
+
+python_prepare_all() {
+	# prevent non essential d'load of files in doc build
+	sed -e 's:intersphinx_:#&:' -i docs/conf.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	if use doc ; then
+		"${PYTHON}" setup.py build_sphinx || die
+	fi
+}
+
+python_test() {
+	"${PYTHON}" ${PN}/tests.py -v || die "Tests fail with ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/_build/html/. )
+	distutils-r1_python_install_all
+}