1 files changed, 42 insertions, 0 deletions
diff --git a/dev-python/django-auth-ldap/django-auth-ldap-1.2.6.ebuild b/dev-python/django-auth-ldap/django-auth-ldap-1.2.6.ebuild
new file mode 100644
index 00000000000..03f5f912371
--- /dev/null
+++ b/dev-python/django-auth-ldap/django-auth-ldap-1.2.6.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+# Although setup.py claims to support py3, python-ldap does not
+PYTHON_COMPAT=( python2_7 pypy )
+
+inherit distutils-r1
+
+DESCRIPTION="Django LDAP authentication backend"
+HOMEPAGE="http://pypi.python.org/pypi/django-auth-ldap http://bitbucket.org/psagers/django-auth-ldap/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+KEYWORDS="~amd64 ~x86"
+IUSE="doc test"
+
+LICENSE="BSD"
+SLOT="0"
+
+RDEPEND="dev-python/django[${PYTHON_USEDEP}]
+		>=dev-python/python-ldap-2.0[${PYTHON_USEDEP}]"
+DEPEND="app-arch/unzip
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? ( ${RDEPEND}
+		>=dev-python/mockldap-0.2[${PYTHON_USEDEP}] )
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )"
+
+PATCHES=( "${FILESDIR}"/docs.patch )
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_test() {
+	PYTHONPATH=. "${PYTHON}" test/manage.py test || die
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/build/html/. )
+	distutils-r1_python_install_all
+}