1 files changed, 49 insertions, 0 deletions
diff --git a/dev-python/docker-py/docker-py-1.1.0-r2.ebuild b/dev-python/docker-py/docker-py-1.1.0-r2.ebuild
new file mode 100644
index 00000000000..b88b834343e
--- /dev/null
+++ b/dev-python/docker-py/docker-py-1.1.0-r2.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+PYTHON_COMPAT=( python2_7 python3_3 python3_4 )
+
+inherit distutils-r1 vcs-snapshot
+
+DESCRIPTION="Python client for Docker"
+HOMEPAGE="https://github.com/docker/docker-py"
+SRC_URI="https://github.com/docker/${PN}/archive/${PV}.tar.gz -> ${P}-r1.tar.gz"
+
+S="${S}-r1"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="doc test"
+
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? ( >=dev-python/mkdocs-0.9[${PYTHON_USEDEP}] )
+	test? (
+		>=dev-python/coverage-3.7.1[${PYTHON_USEDEP}]
+		>=dev-python/mock-1.0.1[${PYTHON_USEDEP}]
+	)
+"
+RDEPEND="
+	>=dev-python/requests-2.5.2[${PYTHON_USEDEP}]
+	>=dev-python/six-1.3.0[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '>=dev-python/websocket-client-0.11.0[${PYTHON_USEDEP}]' python2_7)
+"
+
+python_compile_all() {
+	if use doc; then
+		mkdocs build || die "docs failed to build"
+	fi
+}
+
+python_test() {
+	"${PYTHON}" tests/test.py || die "tests failed under ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( site/. )
+
+	distutils-r1_python_install_all
+}