1 files changed, 45 insertions, 0 deletions
diff --git a/dev-python/eventlet/eventlet-0.13.0.ebuild b/dev-python/eventlet/eventlet-0.13.0.ebuild
new file mode 100644
index 00000000000..3bb3d9b5656
--- /dev/null
+++ b/dev-python/eventlet/eventlet-0.13.0.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+PYTHON_COMPAT=( python2_7 )
+
+inherit distutils-r1
+
+DESCRIPTION="Highly concurrent networking library"
+HOMEPAGE="http://pypi.python.org/pypi/eventlet"
+SRC_URI="mirror://pypi/e/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="amd64 x86"
+IUSE="doc examples test"
+
+RDEPEND=">=dev-python/greenlet-0.3[${PYTHON_USEDEP}]"
+DEPEND="doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	test? ( ${RDEPEND}
+			dev-python/pyopenssl[${PYTHON_USEDEP}]
+			dev-python/nose[${PYTHON_USEDEP}] )"
+
+python_compile_all() {
+	use doc && emake -C doc html
+}
+
+src_test() {
+	# Tests bind to static addresses, bug #456920
+	local DISTUTILS_NO_PARALLEL_BUILD=1
+
+	distutils-r1_src_test
+}
+
+python_test() {
+	nosetests || die "Tests fail with ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( doc/_build/html/. )
+	use examples && local EXAMPLES=( examples/. )
+	distutils-r1_python_install_all
+}