1 files changed, 46 insertions, 0 deletions
diff --git a/dev-python/flask-openid/flask-openid-1.2.4.ebuild b/dev-python/flask-openid/flask-openid-1.2.4.ebuild
new file mode 100644
index 00000000000..387208c8082
--- /dev/null
+++ b/dev-python/flask-openid/flask-openid-1.2.4.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+PYTHON_COMPAT=( python2_7 )
+
+inherit distutils-r1
+
+MY_PN="Flask-OpenID"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="OpenID support for Flask"
+HOMEPAGE="http://pypi.python.org/pypi/Flask-OpenID"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="amd64 x86"
+IUSE="doc examples"
+
+RDEPEND="
+	>=dev-python/flask-0.3[${PYTHON_USEDEP}]
+	>=dev-python/python-openid-2.0[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )"
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]"
+
+S="${WORKDIR}/${MY_P}"
+
+python_prepare_all() {
+	# Prevent un-needed d'loading
+	sed -e "s/, 'sphinx.ext.intersphinx'//" -i docs/conf.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	use doc && esetup.py build_sphinx
+}
+
+python_install_all() {
+	use examples && local EXAMPLES=( example/. )
+	use doc && local HTML_DOCS=( docs/_build/html/. )
+	distutils-r1_python_install_all
+}