1 files changed, 50 insertions, 0 deletions
diff --git a/dev-python/flask-pymongo/flask-pymongo-0.3.1.ebuild b/dev-python/flask-pymongo/flask-pymongo-0.3.1.ebuild
new file mode 100644
index 00000000000..93a03fe8632
--- /dev/null
+++ b/dev-python/flask-pymongo/flask-pymongo-0.3.1.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+PYTHON_COMPAT=( python{2_7,3_3,3_4} )
+
+inherit distutils-r1
+
+MY_PN="Flask-PyMongo"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="PyMongo support for Flask"
+HOMEPAGE="http://pypi.python.org/pypi/Flask-PyMongo"
+SRC_URI="https://github.com/dcrosta/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+#SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc examples"
+RESTRICT="test"
+
+RDEPEND=">=dev-python/flask-0.8[${PYTHON_USEDEP}]
+	>=dev-python/pymongo-2.4[${PYTHON_USEDEP}]
+	<dev-python/pymongo-3.0[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )"
+
+PATCHES=( "${FILESDIR}"/docbuild.patch )
+
+python_prepare_all() {
+	# Req'd to avoid file collisions
+	sed -e s":find_packages():find_packages(exclude=['tests']):" -i setup.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+# Testsuite appears to require a running local instance of a pymongo server
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/_build/html/. )
+	use examples && local EXAMPLES=( examples/. )
+	distutils-r1_python_install_all
+}