1 files changed, 44 insertions, 0 deletions
diff --git a/dev-python/flask-script/flask-script-2.0.5.ebuild b/dev-python/flask-script/flask-script-2.0.5.ebuild
new file mode 100644
index 00000000000..135719a0af9
--- /dev/null
+++ b/dev-python/flask-script/flask-script-2.0.5.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+PYTHON_COMPAT=( python{2_7,3_3,3_4} pypy )
+
+inherit distutils-r1
+
+MY_PN="Flask-Script"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="Flask support for writing external scripts"
+HOMEPAGE="http://packages.python.org/Flask-Script/ http://pypi.python.org/pypi/Flask-Script"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="amd64 x86"
+IUSE="doc test"
+
+RDEPEND=">=dev-python/flask-0.10.1-r1[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	test? ( dev-python/pytest[${PYTHON_USEDEP}] )"
+
+S="${WORKDIR}/${MY_P}"
+
+python_compile_all() {
+	if use doc; then
+		einfo "Generation of documentation by" ${PYTHON}
+		PYTHONPATH=".." emake -C docs html || die "Generation of documentation failed"
+	fi
+}
+
+python_test() {
+	py.test tests.py || die "Tests failed under ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/_build/html/. )
+	distutils-r1_python_install_all
+}