1 files changed, 44 insertions, 0 deletions
diff --git a/dev-python/mysql-python/mysql-python-1.2.5.ebuild b/dev-python/mysql-python/mysql-python-1.2.5.ebuild
new file mode 100644
index 00000000000..9236c57a5c8
--- /dev/null
+++ b/dev-python/mysql-python/mysql-python-1.2.5.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+PYTHON_COMPAT=( python2_7 )
+
+inherit distutils-r1 flag-o-matic
+
+MY_PN="MySQL-python"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="Python interface to MySQL"
+HOMEPAGE="http://sourceforge.net/projects/mysql-python/ http://pypi.python.org/pypi/MySQL-python"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.zip"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="alpha amd64 arm hppa ia64 ppc ppc64 ~s390 ~sh sparc x86 ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="doc"
+
+RDEPEND="virtual/mysql"
+DEPEND="${RDEPEND}
+	app-arch/unzip
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )"
+
+S="${WORKDIR}/${MY_P}"
+
+DOCS=( HISTORY README.md doc/{FAQ,MySQLdb}.rst )
+
+python_configure_all() {
+	append-flags -fno-strict-aliasing
+}
+
+python_compile_all() {
+	use doc && sphinx-build -b html doc doc/_build/
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( doc/_build/. )
+	distutils-r1_python_install_all
+}