1 files changed, 45 insertions, 0 deletions
diff --git a/dev-python/openpyxl/openpyxl-2.1.0.ebuild b/dev-python/openpyxl/openpyxl-2.1.0.ebuild
new file mode 100644
index 00000000000..a2dfde0a1af
--- /dev/null
+++ b/dev-python/openpyxl/openpyxl-2.1.0.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+PYTHON_COMPAT=( python2_7 python3_{3,4} )
+
+inherit distutils-r1 vcs-snapshot
+
+DESCRIPTION="Pure python reader and writer of Excel OpenXML files"
+HOMEPAGE="http://openpyxl.readthedocs.org"
+SRC_URI="https://bitbucket.org/ericgazoni/openpyxl-328/get/${PV}.tar.bz2 -> ${P}.tar.bz2"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="amd64 ~arm x86 ~amd64-linux ~x86-linux"
+IUSE="doc test"
+
+RDEPEND="dev-python/jdcal[${PYTHON_USEDEP}]"
+DEPEND="
+	test? (
+		${RDEPEND}
+		dev-python/pytest[${PYTHON_USEDEP}]
+		dev-python/lxml[${PYTHON_USEDEP}] )
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )"
+
+python_prepare_all(){
+	sed -e "s: 'sphinx.ext.intersphinx',::" \
+		-i doc/source/conf.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	use doc && emake -C doc html
+}
+
+python_test() {
+	py.test || die "Testing failed with ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( doc/build/html/. )
+	distutils-r1_python_install_all
+}