1 files changed, 38 insertions, 0 deletions
diff --git a/dev-python/paramiko/paramiko-1.15.1-r1.ebuild b/dev-python/paramiko/paramiko-1.15.1-r1.ebuild
new file mode 100644
index 00000000000..b6c6c04f593
--- /dev/null
+++ b/dev-python/paramiko/paramiko-1.15.1-r1.ebuild
@@ -0,0 +1,38 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+PYTHON_COMPAT=( python{2_7,3_3,3_4} )
+
+inherit distutils-r1
+
+DESCRIPTION="SSH2 protocol library"
+HOMEPAGE="http://www.paramiko.org/ https://github.com/paramiko/paramiko/ http://pypi.python.org/pypi/paramiko/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="alpha amd64 arm hppa ia64 ~mips ppc ppc64 ~s390 ~sh sparc x86 ~x86-fbsd ~x86-interix ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris"
+IUSE="doc examples"
+
+RDEPEND="
+	>=dev-python/pycrypto-2.1[${PYTHON_USEDEP}]
+	!=dev-python/pycrypto-2.4[${PYTHON_USEDEP}]
+	>=dev-python/ecdsa-0.11[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]"
+
+# Required for testsuite
+DISTUTILS_IN_SOURCE_BUILD=1
+
+python_test() {
+	"${PYTHON}" test.py --verbose || die "Tests fail with ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/. )
+	use examples && local EXAMPLES=( demos/. )
+
+	distutils-r1_python_install_all
+}