1 files changed, 58 insertions, 0 deletions
diff --git a/dev-python/pyatspi/pyatspi-2.12.0.ebuild b/dev-python/pyatspi/pyatspi-2.12.0.ebuild
new file mode 100644
index 00000000000..c39ef82669b
--- /dev/null
+++ b/dev-python/pyatspi/pyatspi-2.12.0.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+GCONF_DEBUG="no"
+PYTHON_COMPAT=( python{2_7,3_3,3_4} )
+
+inherit eutils gnome2 python-r1
+
+DESCRIPTION="Python binding to at-spi library"
+HOMEPAGE="http://live.gnome.org/Accessibility"
+
+# Note: only some of the tests are GPL-licensed, everything else is LGPL
+LICENSE="LGPL-2 GPL-2+"
+SLOT="0"
+KEYWORDS="alpha amd64 arm hppa ia64 ppc ppc64 sparc x86"
+IUSE="" # test
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+COMMON_DEPEND="
+	>=dev-libs/atk-2.11.2
+	dev-python/dbus-python[${PYTHON_USEDEP}]
+	>=dev-python/pygobject-2.90.1:3[${PYTHON_USEDEP}]
+	${PYTHON_DEPS}
+"
+RDEPEND="${COMMON_DEPEND}
+	>=sys-apps/dbus-1
+	>=app-accessibility/at-spi2-core-${PV}[introspection]
+	!<gnome-extra/at-spi-1.32.0-r1
+"
+DEPEND="${COMMON_DEPEND}
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	# https://bugzilla.gnome.org/show_bug.cgi?id=689957
+	epatch "${FILESDIR}/${PN}-2.6.0-examples-python3.patch"
+
+	gnome2_src_prepare
+
+	python_copy_sources
+}
+
+src_configure() {
+	python_foreach_impl run_in_build_dir gnome2_src_configure --disable-tests
+}
+
+src_compile() {
+	python_foreach_impl run_in_build_dir gnome2_src_compile
+}
+
+src_install() {
+	python_foreach_impl run_in_build_dir gnome2_src_install
+
+	docinto examples
+	dodoc examples/*.py
+}