1 files changed, 43 insertions, 0 deletions
diff --git a/dev-python/pydispatcher/pydispatcher-2.0.3-r1.ebuild b/dev-python/pydispatcher/pydispatcher-2.0.3-r1.ebuild
new file mode 100644
index 00000000000..9e1598a0dac
--- /dev/null
+++ b/dev-python/pydispatcher/pydispatcher-2.0.3-r1.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+PYTHON_COMPAT=( python2_7 )
+
+inherit distutils-r1
+
+MY_PN="PyDispatcher"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="Multi-producer-multi-consumer signal dispatching mechanism"
+HOMEPAGE="http://pydispatcher.sourceforge.net/ http://pypi.python.org/pypi/PyDispatcher"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~ia64 ~ppc ~x86"
+IUSE="doc examples"
+
+DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]"
+RDEPEND=""
+
+S="${WORKDIR}/${MY_P}"
+
+python_compile_all() {
+	if use doc; then
+		pushd docs/pydoc/ > /dev/null
+		"${PYTHON}" builddocs.py || die "Generation of documentation failed"
+		popd > /dev/null
+	fi
+}
+
+python_test() {
+	"${PYTHON}" -m unittest discover
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/pydoc/. )
+	use examples && local EXAMPLES=( examples/. )
+	distutils-r1_python_install_all
+}